handlers.coffee

class Handlers
  constructor: ->
    @handlers = {}

  register: (handler, registered_class) ->
    @handlers[handler] = registered_class

  instantiate: (handlers, element) ->
    handlers = handlers.replace(/\s/g, '').split(',')
    element.handlers = []
    $.each handlers, (index, handler) =>
      if @handlers[handler]
        instance = new @handlers[handler](element)
        element.handlers.push instance
      else
        throw "Unknown handler " + handler

  destroy: (instances) ->
    if instances
      $.each instances, (index, instance) ->
        instance.destroy() if instance.destroy

@handlers = new Handlers

$(document).on 'pageChanged', ->
  $('[data-handler]').each ->
    handlers.instantiate $(@).attr('data-handler'), @

$ ->
  $(document).trigger 'pageChanged'
  $(document).on(
    'page:done'
    (event, $target, status, url, data) ->
      $(document).find('[data-handler]').each ->
        handlers.destroy @handlers
        delete @handlers
      $(document).trigger 'pageChanged'
  )

overlay-handler.coffee

handlers.register 'Overlay', class
  constructor: (el) ->
    @overlay = $ el
    $(document).on 'overlay:hide', =>
      @hide()
    $(document).on 'overlay:show', =>
      @show()
    @overlay.on 'click', =>
      $(document).trigger 'overlay:hide'

  hide: =>
    $(document).trigger('overlay:hidden')
    @overlay.hide()
    @overlay.removeClass('active')

  show: =>
    $(document).trigger('overlay:showed')
    @overlay.show()
    @overlay.addClass('active')