Mockolate FlexUnit Setup Examples

CreateMockolatesManually.as

package example
{
	import flash.events.Event;
	
	import mockolate.mock;
	import mockolate.nice;
	import mockolate.prepare;
	
	import org.flexunit.assertThat;
	import org.flexunit.async.Async;
	import org.hamcrest.object.isTrue;

	public class CreateMockolatesManually
	{
		public var myClass:MyClass;
		
		[Before(async, order=1)]
		public function prepareMockClasses():void 
		{
			Async.proceedOnEvent(this, prepare(MyClass), Event.COMPLETE);
		}
		
		[Before(order=2)]
		public function setup():void 
		{
			myClass = nice(MyClass);
		}
		
		[Test]
		public function myClass_shouldDoSomething():void 
		{
			mock(myClass).method("doSomething").returns(true);
			
			assertThat(myClass.doSomething(), isTrue());
		}
	}
}

CreateMockolatesUsingRule.as

package example
{
	import mockolate.mock;
	import mockolate.runner.MockolateRule;
	
	import org.flexunit.assertThat;
	import org.hamcrest.object.isTrue;

	public class CreateMockolatesUsingRule
	{
		[Rule]
		public var mocks:MockolateRule = new MockolateRule();
		
		[Mock]
		public var myClass:MyClass;
		
		[Test]
		public function myClass_shouldDoSomething():void 
		{
			mock(myClass).method("doSomething").returns(true);
			
			assertThat(myClass.doSomething(), isTrue());
		}
	}
}

CreateMockolatesUsingRunner.as

package example
{
	import mockolate.mock;
	import mockolate.runner.MockolateRunner;
	
	import org.flexunit.assertThat;
	import org.hamcrest.object.isTrue;

	MockolateRunner;
	
	[RunWith("mockolate.runner.MockolateRunner")]
	public class CreateMockolatesUsingRunner
	{
		[Mock]
		public var myClass:MyClass;
		
		[Test]
		public function myClass_shouldDoSomething():void 
		{
			mock(myClass).method("doSomething").returns(true);
			
			assertThat(myClass.doSomething(), isTrue());
		}
	}
}

MyClass.as

package example
{
	public class MyClass
	{
		public function MyClass()
		{
			super();
		}
		
		public function doSomething():Boolean 
		{
			return false;
		}
	}
}