Search, Updates and Range Indexes

01-refactoring-search.xq

declare namespace ts="http://marklogic.com/MLU/top-songs";

declare function local:build-query($text as xs:string) {
  cts:or-query((
    cts:word-query($text, (), 1),
    cts:element-word-query(
      xs:QName("ts:title"), $text, (), 2 ))) } ;

declare function local:search-rating($song) {
  cts:score($song)
} ;

for $song in cts:search(fn:doc(), local:build-query("night")) [1 to 10]
return <div>
         { xs:string($song//ts:title) } 
         [ { local:search-rating($song) } ]
       </div>

02-raw-results.xq

import module namespace s="http://marklogic.com/appservices/search" at "/MarkLogic/appservices/search/search.xqy";
declare namespace ts="http://marklogic.com/MLU/top-songs";

let $options := 
  <s:options>
    <s:transform-results apply="raw"/>
  </s:options>
  return 
    for $song in s:search("night", $options)/s:result
      return
        <div class="songname">
          { fn:string($song//ts:title) }
        </div>

03-relevance-vs-documenter-order.xq

(: Showing the difference between contains and search - relevance vs doc order :)
declare namespace ts="http://marklogic.com/MLU/top-songs";

for $song in /ts:top-song 
  [ fn:contains(., "night") ] [1 to 10]
return <div>
         { xs:string($song/ts:title) }
       </div>

(: Using URI to get the title from a document :)
import module namespace s="http://marklogic.com/appservices/search" at "/MarkLogic/appservices/search/search.xqy";
declare namespace ts="http://marklogic.com/MLU/top-songs";

for $result in s:search("night")/s:result
  let $title := fn:string( fn:doc($result/@uri)//ts:title )
  return
    <div class="songname">
      { $title }
    </div>

04-testing-updates.xq

declare namespace ts="http://marklogic.com/MLU/top-songs";

(:::::::::::::::::: update ::::::::::::::)
(: xdmp:node-insert-child(
 : (//ts:p[cts:contains(., "yeah")])[6],
 : element stars { "3" } ) :)

(::::::::::: selection ::::::::::::::::::)
(//ts:p[cts:contains(., "yeah")])[6]

05-accessing-document-properties.xq

xdmp:document-properties("/images/Michael-Jackson+The-Way-You-Make-Me-Feel.jpg")

06-rollback-update.xq

declare namespace ts="http://marklogic.com/MLU/top-songs";

for $weeks in //ts:weeks
 let $week  := $weeks/ts:week
 let $count := fn:count ( $week )
 let $last  := fn:max( xs:date( $week ) )
 return (
    xdmp:node-insert-child($weeks, attribute count { $count } ),
    xdmp:node-insert-child($weeks, attribute last  { $last } ) )

07-fix-the-problem.xq

declare namespace ts="http://marklogic.com/MLU/top-songs";

for $week in //ts:weeks/ts:week
  return if ($week castable as xs:date)
         then ()
         else ( xdmp:node-delete($week), "Deleted one node" )

08-after-range-indexes.xq

(: set up range indexes first :)
declare namespace ts="http://marklogic.com/MLU/top-songs";

for $i in cts:element-attribute-values(
  xs:QName("ts:weeks"), xs:QName("count"), (), "frequency-order" )
return
  <count i="{$i}">
  { cts:frequency($i) }
  </count>