Minimal project demonstrating a problem with elm-community/parser-combinators

CombineProblem.elm

module CombineProblem exposing (..)

import Html
import Combine exposing (..)
import Combine.Num exposing (int)

main =
    parse command "[5M]"
    |> toString
    |> Html.text

type Command
    = Simple Action
    | Repeat Int Command

type Action
    = Move

command: Parser s Command
command =
    choice [primitive, repetition]

primitive: Parser s Command
primitive =
    string "M" $> Simple Move

repetition: Parser s Command
repetition =
    let
        repeatCommand : Parser s Command
        repeatCommand =
            int |> andThen what

        what : Int -> Parser s Command
        what n =
            command |> map (Repeat n)
    in
        brackets repeatCommand

This problem is similar to the problems expressed in #7, #14 and #23.

It is resolved by using the lazy combinator.

command: Parser s Command
command =
    lazy (\() -> choice [primitive, repetition])

primitive: Parser s Command
primitive =
    string "M" $> Simple Move

repetition: Parser s Command
repetition =
    let
        repeatCommand : Parser s Command
        repeatCommand =
            int |> andThen what

        what : Int -> Parser s Command
        what n =
            command |> map (Repeat n)
    in
        lazy (\() -> brackets repeatCommand)