multicast

multicast.rkt

#lang racket/base

(require racket/async-channel)

(provide multicast?
         (rename-out (new-multicast multicast))
         multicast-put
         multicast-get-evt)
         

;; multicast event
(struct multicast (listeners))

(define (new-multicast)
  (multicast (make-weak-hash)))

(define (multicast-put m v)
  (for ([listener (in-hash-keys (multicast-listeners m))])
    (async-channel-put listener v)))

(define (multicast-get-evt m)
  (define fresh-listener (make-async-channel))
  (hash-set! (multicast-listeners m) fresh-listener #t)
  fresh-listener)


(module* test racket/base
  (require (submod ".."))
  (define mc (multicast))
  (define N 10)
  (define evts (for/list ([i N]) (multicast-get-evt mc)))
  (define threads (for/list ([evt evts]
                             [i (in-naturals)])
                    (thread (lambda ()
                              (log-info "~a waiting" i)
                              (log-info "~a ~s" i (sync evt))))))
  (set! evts '())
  (multicast-put mc "hi"))