RemoteLoadGen.cmd

RemoteLoadGen.cmd

@echo off

rem JMeter start script on remote Agulhas server
rem
rem Depending on the name of the script it will run on that host
rem
rem Usage: %~n0 [JMETER FOLDER] [JMETER SCRIPT.jmx] [extra1] [extra2] [...]
rem

for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"

if "%2"=="" (
    for %%f in (*.jmx) do set script=%%~nf
) else (
    for %%f in (%2) do set script=%%~nf
)

set loadgen=%~n0
set JMETER_HOME=%1
set "datestamp=%YYYY%%MM%%DD%" & set "timestamp=%HH%%Min%%Sec%"
set "fullstamp=%YYYY%-%MM%-%DD%_%HH%-%Min%-%Sec%"
set "jtlstamp=%logs%%loadgen%_%script%_%YYYY%-%MM%-%DD%_%HH%-%Min%-%Sec%.jtl"
set "logstamp=%logs%%loadgen%_%script%_%YYYY%-%MM%-%DD%_%HH%-%Min%-%Sec%.log"

for /f "tokens=2,* delims= " %%a in ("%*") do set ALL_BUT_FIRST=%%b

set LAUNCH="sh %jmeter_home%/jmeter.sh -n -l %jtlstamp% -t %script%.jmx -j %logstamp% %ALL_BUT_FIRST%"

echo Load generator: %~n0
echo Running JMeter script %script%
echo JTL results in %jtlstamp% 
echo Jmeter log in %logstamp% 
echo Extra parameters: %ALL_BUT_FIRST%
echo.
echo Launching %LAUNCH%
echo.

@rem copy script to remote host
scp %script%.jmx %loadgen%:.

@rem copy depdencies to remote host
if exist depends.txt (
	for /f "tokens=*" %%a in (depends.txt) do (
	  echo line=%%a
	 
	  scp %%a %loadgen%:.
	)
)

@rem launch generator
ssh %loadgen% %LAUNCH%

@echo on

scp %loadgen%:./%jtlstamp% %jtlstamp%
scp %loadgen%:./%logstamp% %logstamp%