LOBOSLLC Demo: Kynetx Event Action Walkabout

Catch_Event_Raised_Remote_Callback.krl

rule Catch_Event_Raised_Remote_Callback {
    select when web event_remote_callback
    pre {
        callback_rid = event:param("callback_rid");
        callback_evt = event:param("callback_evt");
    }
    {
        notify("Catch_Remote_Callback", "Received from remote Ruleset!") with sticky = true;
        notify("Now Raise Callback", "rid: "+callback_rid+" name: "+callback_evt) with sticky = true;
        raise_event(callback_evt) with app_id = callback_rid;
    }
}

Catch_Event_Raised_Remote_Ruleset.krl

rule Catch_Event_Raised_Remote_Ruleset {
    select when web event_remote_ruleset
    {
        notify("Catch_Remote_Event", "Received from remote Ruleset!") with sticky = true;
    }
}

Kynetx_Event_Action_Walkabout.krl

ruleset a169x258 {
    meta {
        name "Kynetx_Event_Action_Walkabout"
        description <<
            LOBOSLLC Demo: Kynetx Event Action Walkabout
        >>
        author "Ed Orcutt, LOBOSLLC"
        logging on
    }

    global {
        Remote_Ruleset = "a169x259";
        Local_Ruleset  = "a169x258";
    }

    // ------------------------------------------------------------------
    // Raise an Event Action within the same Ruleset
    
    rule Raise_Event_Action_Within_Ruleset is active {
        select when pageview ".*"
        {
            notify("Kynetx Event Walkabout", "Raise_Event_Action_Within_Ruleset") with sticky = true;
            raise_event("event_within_ruleset");
        }
    }
    
    rule Catch_Event_Raised_Within_Ruleset {
        select when web event_within_ruleset
        {
            notify("Catch_Local_Event", "Received Within Ruleset!") with sticky = true;
        }
    }

    // ------------------------------------------------------------------
    // Raise an Event Action to a remote Ruleset
    
    rule Raise_Event_Action_To_Remote_Ruleset is active {
        select when pageview ".*"
        {
            notify("Kynetx Event Walkabout", "Raise_Event_To_Remote_Ruleset") with sticky = true;
            raise_event("event_remote_ruleset") with app_id = Remote_Ruleset;
        }
    }

    // ------------------------------------------------------------------
    // Raise an Event Action to a remote Ruleset

    rule Raise_Event_Action_To_Remote_Ruleset_Callback is active {
        select when pageview ".*"
        {
            notify("Kynetx Event Walkabout", "Raise_Remote_Ruleset_Callback") with sticky = true;
            raise_event("event_remote_callback") with app_id = Remote_Ruleset
                and parameters = {
                    "callback_rid" : Local_Ruleset,
                    "callback_evt" : "event_callback"
                    };
        }
    }

    // ------------------------------------------------------------------
    // Receive Callback Event from remote Ruleset

    rule Catch_Event_Callback_From_Remote_Ruleset {
        select when web event_callback
        {
            notify("Catch_Event_Callback", "Received Callback Event!") with sticky = true;
        }
    }
}

Kynetx_Event_Action_Walkabout_Remote.krl

ruleset a169x259 {
    meta {
        name "Kynetx_Event_Action_Walkabout_Remote"
        description <<
            LOBOSLLC Demo: Kynetx Event Action Walkabout Remote Ruleset
        >>
        author "Ed Orcutt, LOBOSLLC"
        logging on
    }

    // ------------------------------------------------------------------
    // Receive Event from another Ruleset
    
    rule Catch_Event_Raised_Remote_Ruleset {
        select when web event_remote_ruleset
        {
            notify("Catch_Remote_Event", "Received from remote Ruleset!") with sticky = true;
        }
    }

    // ------------------------------------------------------------------
    // Receive Event from another Ruleset with a Callback

    rule Catch_Event_Raised_Remote_Callback {
        select when web event_remote_callback
        pre {
            callback_rid = event:param("callback_rid");
            callback_evt = event:param("callback_evt");
        }
        {
            notify("Catch_Remote_Callback", "Received from remote Ruleset!") with sticky = true;
            notify("Now Raise Callback", "rid: "+callback_rid+" name: "+callback_evt) with sticky = true;
            raise_event(callback_evt) with app_id = callback_rid;
        }
    }
}

Raise_Event_Action_To_Remote_Ruleset.krl

rule Raise_Event_Action_To_Remote_Ruleset is inactive {
    select when pageview ".*"
    {
        notify("Kynetx Event Walkabout", "Raise_Event_To_Remote_Ruleset") with sticky = true;
        raise_event("event_remote_ruleset") with app_id = Remote_Ruleset;
    }
}

Raise_Event_Action_To_Remote_Ruleset_Callback.krl

rule Raise_Event_Action_To_Remote_Ruleset_Callback is inactive {
    select when pageview ".*"
    {
        notify("Kynetx Event Walkabout", "Raise_Remote_Ruleset_Callback") with sticky = true;
        raise_event("event_remote_callback") with app_id = Remote_Ruleset
            and parameters = {
                "callback_rid" : Local_Ruleset,
                "callback_evt" : "event_callback"
                };
    }
}

rule Catch_Event_Callback_From_Remote_Ruleset {
    select when web event_callback
    {
        notify("Catch_Event_Callback", "Received Callback Event!") with sticky = true;
    }
}

Raise_Event_Action_Within_Ruleset.krl

rule Raise_Event_Action_Within_Ruleset is active {
    select when pageview ".*"
    {
        notify("Kynetx Event Walkabout", "Raise_Event_Action_Within_Ruleset") with sticky = true;
        raise_event("event_within_ruleset");
    }
}

rule Catch_Event_Raised_Within_Ruleset {
    select when web event_within_ruleset
    {
        notify("Catch_Local_Event", "Received Within Ruleset!") with sticky = true;
    }
}