Query Seedfeeder works

result.tsv

Seedfeeder.sparql

# https://commons-query.wikimedia.org/sparql?query=...
#   accept: application/sparql-results+json
#   cookie: wcqsOauth=fce1...

# https://www.wikidata.org/wiki/EntitySchema:E49
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX schema: <http://schema.org/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>

PREFIX commons: <https://commons.wikimedia.org/wiki/>

# https://en.wikipedia.org/wiki/Seedfeeder
SELECT DISTINCT ?filename ?imageUrl ?pageUrl ?date WHERE {
  ?file rdf:type schema:ImageObject;
    (p:P170/pq:P4174) "Seedfeeder";
    schema:contentUrl ?imageUrl.
  OPTIONAL { ?file wdt:P571 ?date. }

  BIND(wikibase:decodeUri(CONCAT("File:", SUBSTR(STR(?imageUrl), 53 ))) AS ?filename)
  FILTER(!(REGEX(?filename, "cropped", "i")))

  BIND(CONCAT(STR(commons:), ?filename) AS ?pageUrl)
}
ORDER BY (?date)
LIMIT 100

jq -r '.head.vars|@tsv' result.json > result.tsv
jq -r '.results.bindings[]|[.filename.value, .pageUrl.value, .imageUrl.value, .date.value]|@tsv' result.json >> result.tsv