AoC Day5 solution

day5.ex

defmodule Polymer do
  defstruct data: []

  def new do
    %Polymer{}
  end

  def size(%Polymer{data: data}) do
    data |> Enum.count()
  end

  defimpl Collectable do
    def into(%Polymer{data: data}) do
      collector_fun = fn
        [] = data, {:cont, elem} ->
          [elem | data]

        [last | rest] = data, {:cont, elem} ->
          cond do
            elem == last -> [elem | data]
            elem != last && String.capitalize(elem) == String.capitalize(last) -> rest
            true -> [elem | data]
          end

        data, :done ->
          %Polymer{data: data}

        _, :halt ->
          :ok
      end

      {data, collector_fun}
    end
  end
end

defmodule Day5 do
  def part1 do
    [line | _rest] = File.read!("input.txt") |> String.split("\n", trim: true)

    line
    |> String.split("", trim: true)
    |> compute_polymer
  end

  def part2 do
    [line | _rest] = File.read!("input.txt") |> String.split("\n", trim: true)

    polymer =
      line
      |> String.split("", trim: true)
      |> generate_clean_lists
      |> Enum.min_by(fn polymer ->
        Polymer.size(polymer)
      end)

    Polymer.size(polymer)
  end

  @doc """
  Computes the final polymer size

      iex> Day5.compute_polymer(["a", "b", "B", "c", "D", "d", "a"])
      3
  """
  def compute_polymer(chars) do
    polymer = for char <- chars, do: char, into: Polymer.new()

    Polymer.size(polymer)
  end

  def generate_clean_lists(chars) do
    Enum.map(?a..?z, fn x -> <<x::utf8>> end)
    |> Enum.map(fn char ->
      clean_chars =
        Enum.reject(chars, fn x ->
          String.capitalize(x) == String.capitalize(char)
        end)

      for char <- clean_chars, do: char, into: Polymer.new()
    end)
  end
end