winkey was an old program. this autohotkey provides shortcuts to override some of windows (virtual desktop), and add some, sleep improves opening is important., back in the happy days of Windows 95+ that allowed quickly launching programs using the windows key combinations. replaced by autohotkey and cool dll capabilities. sleep before action in…

winkey.ahk

#Requires AutoHotkey v2.0
#SingleInstance  force         ; skip prompt and replace old instance automatically.
ListLines        false              ; disable key history / script lines listing for efficiency.
SetWorkingDir    A_ScriptDir  ; set working folder to be the script's folder.

;---------------------------------------------------------------------
; WIN+1 - my computer
; WIN+3 - C:\
; WIN+SHIFT+3 - karakocom c
; WIN+5 - D:\
; WIN+SHIFT+5 - karakocom d
; WIN+PrintScr - PrintScreen PrintScr [windows]+[print-screen] to show my computer advance properties.
; WIN+H - HOSTS file, via notepad++, as admin
; WIN+DEL - Windows's uninstall or change program 
; WIN+SHIFT+DEL - ccleaner
; WIN+CTRL+DEL - Bulk-Crap-Uninstaller
; WIN+SHIFT+R - register-workshop
; WIN+CTRL+D - desktop folder in explorer.exe
; WIN+SHIFT+CTRL+D - karakocom desktop folder in explorer.exe
; WIN+D - minimize all windows/restore all windows (toggle)
; WIN+M - minimize current active window
; WIN+N - maximize current active window
; WIN+B - restore current active window
;---------------------------------------------------------------------
;


#1:: {
        Sleep 60  ; allow shell to restore
        Run "::{20D04FE0-3AEA-1069-A2D8-08002B30309D}",,"Max"
}

#3:: {
        Run "C:\",,"Max"
        Sleep 60  ; allow shell to restore
}

#+3:: {
        Run "N:\",, "Max"
        Sleep 60  ; allow shell to restore
}

#5:: {
        Run "D:\",,"Max"
        Sleep 60  ; allow shell to restore
}


#+5:: {
  Sleep 300  ; allow shell to restore
  Run "M:\",,"Max"
  Sleep 30  ; allow shell to restore
}


#PrintScreen:: {
  Sleep 300  ; allow shell to restore
  Run "C:\Windows\System32\systempropertiesadvanced.exe",,"Max"
  ;DllCall("C:\Windows\System32\sysdm.cpl\EditEnvironmentVariables")
}


#h:: {
  Sleep 300  ; allow shell to restore
  DllCall("shell32.dll\ShellExecuteW"
        , "ptr", 0                                            ;hwnd == 0, no owner window, detached.
        , "wstr", "runas"                                     ;elevated (admin) open
        , "wstr", "D:\software\notepad++\notepad++.exe"       ;target path
        , "wstr", A_WinDir . "\System32\drivers\etc\hosts"    ;target arguments
        , "wstr", A_WinDir . "\System32\drivers\etc\hosts"    ;target directory
        , "int",  3                                           ;SW_SHOWMAXIMIZED == 3 - Activates the window and displays it as a maximized window. https://learn.microsoft.com/en-us/windows/win32/api/winuser/nf-winuser-showwindow
  )
}


#Del:: {
  Sleep 300  ; allow shell to restore
  DllCall("shell32.dll\ShellExecuteW"
        , "ptr", 0                                            ;hwnd == 0, no owner window, detached.
        , "wstr", "runas"                                     ;elevated (admin) open
        , "wstr", A_WinDir . "\System32\control.exe"          ;target path
        , "wstr", A_WinDir . "\System32\appwiz.cpl"           ;target arguments
        , "wstr", A_WinDir . "\System32"                      ;target directory
        , "int",  3                                           ;SW_SHOWMAXIMIZED == 3 - Activates the window and displays it as a maximized window. https://learn.microsoft.com/en-us/windows/win32/api/winuser/nf-winuser-showwindow
  )
}

#+Del:: {
  Sleep 300  ; allow shell to restore
  DllCall("shell32.dll\ShellExecuteW"
        , "ptr", 0                                                  ;hwnd == 0, no owner window, detached.
        , "wstr", "runas"                                           ;elevated (admin) open
        , "wstr", "D:\software\all security\CCleaner\ccleaner.exe"  ;target path
        , "wstr", ""                                                ;target arguments
        , "wstr", "D:\software\all security\CCleaner"               ;target directory
        , "int",  3                                                 ;SW_SHOWMAXIMIZED == 3 - Activates the window and displays it as a maximized window. https://learn.microsoft.com/en-us/windows/win32/api/winuser/nf-winuser-showwindow
  )
}

#^Del:: {
  Sleep 300  ; allow shell to restore
  DllCall("shell32.dll\ShellExecuteW"
        , "ptr", 0                                                  ;hwnd == 0, no owner window, detached.
        , "wstr", "runas"                                           ;elevated (admin) open
        , "wstr", "D:\software\all security\Bulk-Crap-Uninstaller\BCUninstaller.exe"  ;target path
        , "wstr", ""                                                ;target arguments
        , "wstr", "D:\software\all security\Bulk-Crap-Uninstaller"               ;target directory
        , "int",  3                                                 ;SW_SHOWMAXIMIZED == 3 - Activates the window and displays it as a maximized window. https://learn.microsoft.com/en-us/windows/win32/api/winuser/nf-winuser-showwindow
  )
}


#+r:: {
  Sleep 100  ; allow shell to restore
  DllCall("shell32.dll\ShellExecuteW"
        , "ptr", 0                                                                ;hwnd == 0, no owner window, detached.
        , "wstr", "runas"                                                         ;elevated (admin) open
        , "wstr", "D:\software\all security\Registry Workshop\RegWorkshop64.exe"  ;target path
        , "wstr", ""                                                              ;target arguments
        , "wstr", "D:\software\all security\Registry Workshop"                    ;target directory
        , "int",  3                                                               ;SW_SHOWMAXIMIZED == 3 - Activates the window and displays it as a maximized window. https://learn.microsoft.com/en-us/windows/win32/api/winuser/nf-winuser-showwindow
  )
  Sleep 100  ; allow shell to restore
}


;-------- desktop folder
#^d:: {
  Sleep 100  ; allow shell to restore

  Run A_Desktop,, "Max"

  ;--- alternative way to get special-folder desktop. in-case user has changed the folder from "C:\Users\" . A_UserName . "\Desktop" .
  ;static objShell := ComObject("Shell.Application")   ; local static reusable object (repeat key press will not re-create the object)
  ;static desktop_folder := objShell.Namespace(0)
  ;Run desktop_folder.Self.Path,, "Max"

  Sleep 100  ; allow shell to restore
}


;-------- desktop folder - network device
#^+d:: {
  Sleep 100  ; allow shell to restore
  ;Run "\\karakocom\c$\Users\Elad\Desktop",, "Max"
  Run "N:\Users\Elad\Desktop",, "Max"
  Sleep 100  ; allow shell to restore
}





#d:: {       ;shell32 - "ToggleDesktop" verb, alternative is IShellDispatch::MinimizeAll / UndoMinimizeALL .
  Sleep 100  ; allow shell to restore
  static objShell := ComObject("Shell.Application")   ; local static reusable object (repeat key press will not re-create the object)
  objShell.ToggleDesktop()
  Sleep 100  ; allow shell to restore
}

#m:: { ;--- minimize active window
  Sleep 100  ; allow shell to restore
  WinMinimize("A")
  Sleep 100  ; allow shell to restore
}

#n:: { ;--- maximized active window
  Sleep 100  ; allow shell to restore
  WinMaximize("A")
  Sleep 100  ; allow shell to restore
}

#b:: { ;--- restore active window
  Sleep 100  ; allow shell to restore
  WinRestore("A")
  Sleep 100  ; allow shell to restore
}





;# = WIN
;! = ALT
;^ = CTRL
;+ = SHIFT
;https://eladkarako.github.io/docs_autohotkey_v2/docs/lib/Run.htm
;https://eladkarako.github.io/docs_autohotkey_v2/docs/misc/CLSID-List.htm