gistfile1.txt

# Maintainer: Jan Alexander Steffens (heftig) <[email protected]>
# Maintainer: Fabian Bornschein <[email protected]>

pkgbase=libadwaita
pkgname=(
  libadwaita
)
pkgver=1.7alpha
pkgrel=1
epoch=1
pkgdesc="Building blocks for modern adaptive GNOME applications"
url="https://gnome.pages.gitlab.gnome.org/libadwaita/"
arch=(x86_64)
license=(LGPL-2.1-or-later)
depends=(
  appstream
  fribidi
  glib2
  glibc
  graphene
  gtk4
  pango
)
makedepends=(
  gi-docgen
  git
  glib2-devel
  gobject-introspection
  meson
  sassc
  vala
)
checkdepends=(weston)
source=("git+https://gitlab.gnome.org/GNOME/libadwaita.git#tag=${pkgver/[a-z]/.&}")
b2sums=('c89ee144791433887b7f9367fe5875e015fc7d0029778e73150d983ba0a808b8a7189554264f7e644f649990e6fc870657c22142835aec5688eb22423ab08475')

prepare() {
  cd $pkgname
}

build() {
  local meson_options=(
    -D gtk_doc=true
  )

  arch-meson $pkgname build "${meson_options[@]}"
  meson compile -C build
}

package_libadwaita() {
  depends+=(libgtk-4.so)
  provides+=(libadwaita-1.so)

  meson install -C build --destdir "$pkgdir"

  cd "$pkgdir"

}

# vim:set sw=2 sts=-1 et: