pam_recent

.SRCINFO

pkgbase = pam_recent-git
	pkgdesc = pam_recent is a small PAM module for making iptables' recent match more useful
	pkgver = r12.9c942dc
	pkgrel = 1
	url = https://github.com/az143/pam_recent
	arch = x86_64
	license = GPL
	provides = pam_recent
	conflicts = pam_recent
	source = git+https://github.com/az143/pam_recent.git
	md5sums = SKIP

pkgname = pam_recent-git

PKGBUILD

# Maintainer: Daniel Lin <[email protected]>
pkgname=pam_recent-git
pkgver=r12.9c942dc
pkgrel=1
pkgdesc="pam_recent is a small PAM module for making iptables' recent match more useful"
arch=('x86_64')
url="https://github.com/az143/pam_recent"
license=('GPL')
provides=('pam_recent')
conflicts=('pam_recent')
source=('git+https://github.com/az143/pam_recent.git')
md5sums=('SKIP')

pkgver() {
	cd pam_recent
	printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

build() {
	cd pam_recent
	${CC:-cc} ${CPPFLAGS} ${CFLAGS} -shared -fPIC -Xlinker -x \
	    -o pam_recent.so pam_recent.c -lpam
}

package() {
	cd pam_recent
	install -D -s -t "$pkgdir/usr/lib/security" pam_recent.so
	install -D -m 644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
}