ByeDPI on MikroTik

mikrotik_byedpi.md

ByeDPI на микротик

Подготовка

1. Подключаем феш накопитель к mikrotik и форматируем его в ext4. Легче всего это сделать через winbox

• Заходим в System > Disks > Format drive
• Выбираем slot usb1 и file system ext4, и нажимаем start.
• Ждём пока кнопка start снова не станет доступной.
• Когда стала доступной то всё готово.

2. Нужно установить пакет container.

• Заходим на сайт Software Packages
• Качаем Extra packages для вашей архитектуры.
• Вытаскиваем установочный файл container*.npk и перекидываем в корень файловой системы микротика.
• Включаем container в микротике.

  /system/device-mode update container=yes
  

• Перезапускаем роутер.

  /system reboot
  

• После перезапуска пакет из файловой системы пропадет и добавиться пункт в winbox, container.

3. Настройка container.

• Надо зарегистрироваться на docker.io.
• После регистрации вводим такую команду, там где username и password это ваши логин и пароль из docker.io.

  /container/config set registry-url=https://registry-1.docker.io tmpdir=/usb1/docker/pull username=<имя_пользователя> password=<пароль>
  

4. Создаём мост для наших будущих контейнеров.

/interface/bridge add name=Bridge-Docker port-cost-mode=short
/ip/address add address=192.168.254.1/24 interface=Bridge-Docker network=192.168.254.0

5. Настраиваем DoH. DNS-DNSoverHTTPS(DoH)

/tool fetch url="https://cacerts.digicert.com/DigiCertGlobalRootCA.crt.pem"
/certificate import file-name=DigiCertGlobalRootCA.crt.pe
/ip dns set use-doh-server=https://cloudflare-dns.com/dns-query verify-doh-cert=yes
/ip dns set servers=1.1.1.1

• Переводим абсолютно все dns запросы через doh кроме локальных:

  /ip/firewall/address-list/ add address=10.0.0.0/8 list=local
  /ip/firewall/address-list/ add address=172.16.0.0/12 list=local
  /ip/firewall/address-list/ add address=192.168.0.0/16 list=local
  /ip firewall nat add action=redirect chain=dstnat dst-address-list=!local dst-port=53 in-interface-list=LAN protocol=udp
  /ip firewall nat add action=redirect chain=dstnat dst-address-list=!local dst-port=53 in-interface-list=LAN protocol=tcp
  

• Заходим на https://www.dnsleaktest.com/ и проверяем чтобы был dns Cloudflare

Настройка ByeDPI

1. Делаем виртуальный ether для нашего контейнера.

/interface/veth add address=192.168.254.5/24 gateway=192.168.254.1 name=BYEDPI-SOCKS

• Также настраиваем bridge port.

  /interface/bridge/port add bridge=Bridge-Docker interface=BYEDPI-SOCKS
  

2. Скачиваем и запускаем контейнер.

/container/add remote-image=tazihad/byedpi:latest interface=BYEDPI-SOCKS cmd="-s 1 --disorder 1 --auto=torst --tlsrec 1+s --debug 1" root-dir=/usb1/docker/byedpi start-on-boot=yes dns=1.1.1.1
/container start [find interface=BYEDPI-SOCKS]

• Теперь можно подключиться через любой socks клиент к нашему контейнеру через ip 192.168.254.5 и port 1080.

Настройка TUN2SOCKS, а точнее hev-socks5-tunnel

1. Делаем виртуальный ether для нашего контейнера.

/interface/veth add address=192.168.254.2/24 gateway=192.168.254.1 name=TUN2SOCKS

• Также настраиваем bridge port.

  /interface/bridge/port add bridge=Bridge-Docker interface=TUN2SOCKS
  

2. Скачиваем и запускаем контейнер.

• Задаём envs для нашего контейнера.

  /container/envs/ add key=LOCAL_ROUTE name=tun2socks value="ip r a 192.168.0.0/16 via 192.168.254.1;ip r a 10.0.0.0/8 via 192.168.254.1;ip r a 172.16.0.0/12 via 192.168.254.1"
  /container/envs/ add key=SOCKS5_ADDR name=tun2socks value=192.168.254.5
  

• Скачиваем контейнер.

  /container/add remote-image=snegowiki/hev-socks5-tunnel-mikrotik:test interface=TUN2SOCKS root-dir=usb1/docker/hev-socks5-tunnel start-on-boot=yes envlist=tun2socks
  

• Запускаем контейнер.

  /container start [find interface=TUN2SOCKS]
  

3. Настраиваем срок dns адрессов.

/ip/dns set address-list-extra-time=1d

4. Настраиваем таблицы маршрутов.

/routing table add disabled=no fib name=dpi_mark
/ip route add disabled=no distance=22 dst-address=0.0.0.0/0 gateway=192.168.254.2%Bridge-Docker pref-src="" routing-table=dpi_mark scope=30 suppress-hw-offload=no target-scope=10

5. Делаем mangle правило для заворачивания наших хостов в таблицу маршрутов.

/ip firewall mangle add action=mark-connection chain=prerouting connection-mark=no-mark dst-address-list=za_dpi_FWD in-interface-list=LAN new-connection-mark=to_dpi passthrough=yes
/ip firewall mangle add action=mark-routing chain=prerouting comment="To DPI" connection-mark=to_dpi in-interface-list=LAN new-routing-mark=dpi_mark passthrough=no routing-mark=!dpi_mark

6. Отключаем forward fasttrack connection для ускорение роутинга.

/ip firewall filter disable [find action=fasttrack-connection]

• Можно также просто исключить маркированный трафик.

  /ip firewall filter set [find action=fasttrack-connection] packet-mark=no-mark connection-mark=no-mark
  

7. Добавляем хосты которые мы хотим провести через byedpi. Для примера взял ютуб и рутрекер

/ip/dns/static/ add address-list=za_dpi_FWD forward-to=localhost match-subdomain=yes name=googlevideo.com type=FWD
/ip/dns/static/ add address-list=za_dpi_FWD forward-to=localhost match-subdomain=yes name=youtube.com type=FWD
/ip/dns/static/ add address-list=za_dpi_FWD forward-to=localhost match-subdomain=yes name=youtubei.googleapis.com type=FWD
/ip/dns/static/ add address-list=za_dpi_FWD forward-to=localhost match-subdomain=yes name=ytimg.com type=FWD
/ip/dns/static/ add address-list=za_dpi_FWD forward-to=localhost match-subdomain=yes name=youtu.be type=FWD
/ip/dns/static/ add address-list=za_dpi_FWD forward-to=localhost match-subdomain=yes name=ggpht.com type=FWD
/ip/dns/static/ add address-list=za_dpi_FWD forward-to=localhost match-subdomain=yes name=rutracker.org type=FWD
/ip/dns/static/ add address-list=za_dpi_FWD forward-to=localhost match-subdomain=yes name=rutracker.cc type=FWD

8. Чистим dns кеш и перезапускаем роутер:

/ip dns cache flush
/system reboot

возможно у яндекса свой DOH, его нужно отключить

В устройствах яндекса в настройках сети есть только стандартные настройки: статический адрес и dhcp, других настроек нет. Я нашел что под значком ютуба скрывается приложение CoAT:cobalt / com.yandex.tv.ytplayer, видимо в нем есть свои настройки не позволяющие смотреть ютуб в России. В Яндекс ТВ есть возможность подключить флешку и есть файловый менеджер, поэтому отключил это приложение, скачал и установил через флешку приложение Aptoide TV и через него установил YouTube for Android TV. В нем ютуб видео показывает и без проблем тянет 4К, ByeDPI круче VPN ))
Но в других устройствах яндекса (Яндекс Модуль, Яндекс Станция Макс) такой возможности установки сторонних приложений нет, точнее есть, но очень сложная, через медиаплеер VLC и есть вероятность окирпичить устройство. Поэтому, если кто знает как подружить CoAT:cobalt / com.yandex.tv.ytplayer и ByeDPI, напишите.

Не работает YouTube for Android TV без плясок с ByeDPI и VPN , как может показаться из комментария выше

как может показаться из комментария выше

это второй комментарий в продолжении темы, чуть выше есть первый, в котором сообщается, что после настройки ByeDPI на устройствах Яндекса ютуб все равно не работает, а во втором комментарии, что в том случае помогла установка YouTube for Android TV, но не на всех устройствах его легко установить. Поэтому и спросил, как подружить yandex.tv.ytplayer и ByeDPI

Все сделал согласно инструкции, но почему то из списка сайтов добавленных в DNS работает только ютуб. А мне нужно еще Дискорд пробросить

Все сделал согласно инструкции, но почему то из списка сайтов добавленных в DNS работает только ютуб. А мне нужно еще Дискорд пробросить

через byedpi только замедленные сервисы работают, для зблокированных лучше использовать vless.

https://github.com/ergolyam/mikrotik-sing-box