Autologon and Insomnia for Kiosk

kiosk.bat

@echo off

set USERNAME=xxxxxxxxxxxx
set PASSWORD=yyyyyyyyyyyy

whoami /PRIV | find "SeLoadDriverPrivilege" > NUL
if not errorlevel 1 goto :main
powershell.exe -Command Start-Process """%0""" -Verb Runas
exit /b 0

:main
rem Enable auto login
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /v "AutoAdminLogon" /t REG_DWORD /d "1" /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /v "DefaultUserName" /t REG_SZ /d "%USERNAME%" /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /v "DefaultPassword" /t REG_SZ /d "%PASSWORD%" /f

rem Disable lock screen
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\Personalization" /v "NoLockScreen" /t REG_DWORD /d "1" /f

rem Disable screen saver
reg add "HKEY_CURRENT_USER\Control Panel\Desktop" /v ScreenSaveActive /t REG_SZ /d 0 /f
reg add "HKEY_CURRENT_USER\Control Panel\Desktop" /v ScreenSaverIsSecure /t REG_SZ /d 0 /f

rem Power schemes
set POWER_SCHEME_ENERGY_SAVING=a1841308-3541-4fab-bc81-f71556f20b4a
set POWER_SCHEME_BALANCED=381b4222-f694-41f0-9685-ff5bb260df2e
set POWER_SCHEME_HIGHPERFORMANCE=8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c

set POWER_SCHEME_GUID=%POWER_SCHEME_HIGHPERFORMANCE%

rem Don't sleep if AC is connected.
rem   238c9fa8-0aad-41ed-83f4-97be242c8f20: Sleep
rem     29f6c1db-86da-48c5-9fdb-f2b67b1f44da: When sleep (sec.)
powercfg -SETACVALUEINDEX %POWER_SCHEME_GUID% 238c9fa8-0aad-41ed-83f4-97be242c8f20 29f6c1db-86da-48c5-9fdb-f2b67b1f44da 0

rem Don't hibernate if AC is connected.
rem   238c9fa8-0aad-41ed-83f4-97be242c8f20: Sleep
rem     9d7815a6-7ee4-497e-8888-515a05f02364: When hibernate (sec.)
powercfg -SETACVALUEINDEX %POWER_SCHEME_GUID% 238c9fa8-0aad-41ed-83f4-97be242c8f20 9d7815a6-7ee4-497e-8888-515a05f02364 0

rem Don't sleep on lid close
rem   4f971e89-eebd-4455-a8de-9e59040e7347: Power button/lid
rem     5ca83367-6e45-459f-a27b-476b1d01c936: Lid close
powercfg -SETACVALUEINDEX %POWER_SCHEME_GUID% 4f971e89-eebd-4455-a8de-9e59040e7347 5ca83367-6e45-459f-a27b-476b1d01c936 0

rem Don't turn off video
rem   7516b95f-f776-4464-8c53-06167f40cc99: Display
rem     3c0bc021-c8a8-4e07-a973-6b14cbcb2b7e: When turn off (sec.)
powercfg -SETACVALUEINDEX %POWER_SCHEME_GUID% 7516b95f-f776-4464-8c53-06167f40cc99 3c0bc021-c8a8-4e07-a973-6b14cbcb2b7e 0

rem Activate the power scheme anyway
powercfg -SETACTIVE %POWER_SCHEME_GUID%