Example StInspector complex extension with activation

CollectionExtension.st

Collection >> tabInspectorList: builder [
  <inspectorPresentationOrder: 90 title: 'Tab View'>
  
  ^ StCollectionExampleInspection on: self
]

StCollectionExampleInspection.st

Class {
	#name : #StCollectionExampleInspection,
	#superclass : #StInspection,
	#instVars : [
		'notebook',
		'unorderedList',
		'orderedList'
	],
	#category : #'NewTools-Inspector-View'
}

{ #category : #testing }
StCollectionExampleInspection >> hasOutputActivationPort [

	^ true
]

{ #category : #initialization }
StCollectionExampleInspection >> initializePresenters [

	self layout: (SpBoxLayout newTopToBottom
		add: (notebook := self newNotebook);
		yourself).

	orderedList := self newList.
	unorderedList := self newList.
		
	notebook  
		addPage: (SpNotebookPage
			title: 'Raw'
   			icon: (self iconNamed: #nautilusIcon)
			provider: [ unorderedList items: self model; yourself ]);
		addPage: (SpNotebookPage
			title: 'Sorted'
			icon: (self iconNamed: #nautilusIcon)
			provider: [ orderedList items: self model asSortedCollection ])
]

{ #category : #ports }
StCollectionExampleInspection >> outputActivationPort [

	^ unorderedList outputActivationPort, 
	orderedList outputActivationPort
]

mmm... that example misses two methods:

StCollectionExampleInspection >> activateOnSingleClick [

    unorderedList activateOnSingleClick.
    orderedList activateOnSingleClick
]

StCollectionExampleInspection >> activateOnDoubleClick [

    unorderedList activateOnDoubleClick.
    orderedList activateOnDoubleClick
]