test.pl

use strict;
use warnings;
use Test::More;
use Scalar::Util qw/reftype/;

sub redact {
    my ($thing, $replace, @fix) = @_; 
    my %seen;
    my @stack = ($thing);
    while (@stack) {
        my $it = shift @stack;
        next unless ref $it;
        next if $seen{$it}++;
        if (reftype($it) eq 'ARRAY') {
            push @stack => @$it;
            next;
        }   
        elsif (reftype($it) eq 'SCALAR') {
            push @stack => $$it;
            next;
        }   
        elsif (reftype($it) ne 'HASH') {
            next;
        }   

        push @stack => values %$it;

        for my $key (@fix) {
            next unless defined $it->{$key};
            $it->{$key} = $replace;
        }   
    }   
}

sub build {
    my $orig = shift;
    my $inner = {foo => $orig, bar => 'bar'};
    my $scalar = \$inner;
    my $it = { 
        foo => $orig,
        bar => 'bar',
        baz => [
            {foo => $orig},
            {bar => 'bar'},
        ],  
        uhg => $orig,
        bam => $inner,
    };  
    $it->{cycle} = $it;
};

my $foo = build('foo');
my $new = build('new');

redact($foo, 'new', qw/foo uhg/);

is_deeply(
    $foo,
    $new,
    "Modified all necessary keys"
);

done_testing;