ReactNativeCamera.re

[@bs.module "react-native-camera"] [@react.component]
external make:
  (
    ~onBarCodeRead: {. "data": string} => unit=?,
    ~captureAudio: bool,
    ~ref: 'ref=?,
    ~style: ReactNative.Style.t=?,
    ~children: React.element=?
  ) =>
  React.element =
  "RNCamera";

let makeProps = (~captureAudio=false) => makeProps(~captureAudio);

type api = {
  takePictureAsync:
    'a.
    Js.t({..} as 'a) =>
    Promise.rejectable(Belt_Result.t(string, 'a), Promise.never),

  resumePreview: unit => unit,
  pausePreview: unit => unit,
};
let useCameraRef = () => {
  let cameraRef = React.useRef(None);

  let takePictureAsync = config => {
    switch (cameraRef->React.Ref.current) {
    | Some(r) =>
      let promise: Promise.Js.t({. "base64": string}, _) =
        ReasonReact.refToJsObj(r)##takePictureAsync(config);

      promise->Promise.Js.toResult->Promise.mapOk(result => {result##base64});
    | None => Promise.resolved(failwith("Error"))
    };
  };

  let resumePreview = () => {
    switch (cameraRef->React.Ref.current) {
    | Some(r) => ReasonReact.refToJsObj(r)##resumePreview()
    | None => ()
    };
  };

  let pausePreview = () => {
    switch (cameraRef->React.Ref.current) {
    | Some(r) => ReasonReact.refToJsObj(r)##pausePreview()
    | None => ()
    };
  };

  (cameraRef, {takePictureAsync, resumePreview, pausePreview});
};