tintash6.inf

Switches d2xC0;

Constant Story "Tintash^";
Constant Headline "Your First Day At Tintash by Faried Nawaz^";
Release 3;

Constant DIALECT_US;

Include "Parser";
Include "Verblib";

!! if the player tries to go somewhere they can't, list the valid
!! exits.
!! http://www.ifarchive.org/if-archive/infocom/compilers/inform6/library/contributions/smartcantgo.h
Include "smartcantgo";

!! display exits after room description.  it's a slightly
!! modified version of
!! http://www.ifarchive.org/if-archive/infocom/compilers/inform6/library/contributions/dirs_2.h
!! my changes are at https://gist.github.com/faried/8046102
Constant ShowRooms;

Include "dirs_2_fn";

!! default behavior for rooms
Class Room
 with   cant_go [;
            SmartCantGo();
        ],
        after [;
         Look: print "^"; DirsSub();
        ],
 has    light;


Room  Lobby "Tintash Lobby"
 with   description "It's your first day at Tintash!  You've climbed up to
            the third floor and are in the lobby; it is 10:15am.  Most of
            the offices are empty right now, but your co-workers are
            starting to stream in.",
        e_to Hallway;

Room  Hallway "Hallway"
 with   description "You see one of the various engineering rooms to your
            north, and the art department is on your south.",
        w_to Lobby,
        n_to EngRoom,
        s_to ArtDept;

Room EngRoom "Engineering Room"
 with   description "You see a brightly decorated room with several
            trolls... er, I mean, engineers typing away at their laptops.",
        s_to Hallway;

Object -> Engineers "engineers"
 with   name 'engineer' 'engineers' 'troll' 'trolls',
        description "They look busy, but you think you spy a few Facebook
            tabs open in their browser windows..."
 has    scenery concealed pluralname;

Object -> Windows "windows"
 with   name 'tab' 'tabs' 'facebook' 'browser' 'display' 'displays'
            'editor' 'editors',
        description "As you lean in to peer at their displays, the users
            quickly switch back to their editors, and get back to work.",
        after [;
         Examine, Look:
            Windows.description = "Oodles of code stream across the displays,
                in fonts too tiny to read.";
            Engineers.description = "They are busy debugging some code.";
        ],
 has    scenery concealed pluralname;

Object -> Saad "Saad"
 with   description "Saad is getting ready to complete and release another
            game.  He looks busy.",
        initial "As you enter the room, you see Saad at his desk.  He looks
            up when you come in, and then goes back to work.",
        life [;
         Ask: "He seems busy.  Perhaps this is not the best time to disturb him.";
         Tell: "Saad asks that you wait until he's done.";
         ]
 has    animate;

Room ArtDept "Art Department"
 with   description "There is a large wooden table in the center of the room,
            surrounded by several empty chairs.  Sardar, the head designer and
            chief mustache twirler, is not in yet (after all, it's only
            10:15am).",
        n_to Hallway;

Object -> ArtTable "wooden table"
 with   name 'table',
        description "It is an oblong, dark wooden table."
 has    scenery concealed;

Object -> ArtChairs "chairs"
 with   name 'chair' 'chairs',
        description "New chairs!  At last!"
 has    scenery concealed pluralname;

Object -> Sardar "Sardar"
 with   description "Sardar isn't here right now.",
 has    scenery concealed;

[ Initialise;
    location = Lobby;
];

Include "grammar";

Verb 'talk'
    * 'to' noun                         -> Talk
    * noun                              -> Talk;

[ TalkSub;
    "It's your first day -- you must have a lot of questions, but right now's not the time.";
];

!! eof