OmniGraffle: Export layers on top of base-layer as PNG

README.md

Layer export for OmniGraffle

If you have a Graffle document (doc.graffle) with a canvas named "mycanvas" holding the following layers ...

• Extra 3
• Extra 2
• Extra 1
• Base

... then these images will be generated:

• doc.graffle-mycanvas-1.png (Layers: Base)
• doc.graffle-mycanvas-2.png (Layers: Base + Extra 1)
• doc.graffle-mycanvas-3.png (Layers: Base + Extra 1 + Extra 2)
• doc.graffle-mycanvas-4.png (Layers: Base + Extra 1 + Extra 2 + Extra 4)

layer-export-single-out-layers.applescript

tell application "OmniGraffle"
	set thisWindow to first window
	set thisDocument to front document
	set thisCount to 0
	set win_layers to (thisWindow's canvas's layers)
	set canvasName to (thisWindow's canvas's name)
	set area type of current export settings to current canvas
	
	-- First, make all layers invisible except the base layer:
	repeat with win_layer from 1 to (count win_layers)
		set thisLayer to item win_layer of win_layers
		set visible of thisLayer to (name of thisLayer = "Base")
	end repeat
	
	-- Now, show each layer, export the image, and make the layer invisible again:
	repeat with win_layer from 1 to (count win_layers)
		set thisLayer to item win_layer of win_layers
		set visible of thisLayer to true
		set thisCount to thisCount + 1
		set targetFile to (thisDocument's path & "-" & canvasName & "-" & thisCount & ".png")
		save thisDocument as "PNG" in POSIX file targetFile
		set visible of thisLayer to false
	end repeat
	
	-- Make all layers visible again:
	repeat with win_layer from 1 to (count win_layers)
		set thisLayer to item win_layer of win_layers
		set visible of thisLayer to true
	end repeat
end tell

layer-export.applescript

tell application "OmniGraffle"
	set thisWindow to first window
	set thisDocument to front document
	set thisCount to 0
	set win_layers to (thisWindow's canvas's layers)
	set canvasName to (thisWindow's canvas's name)
	set area type of current export settings to current canvas
	
	-- First we have to make every layer except for the 
	-- base layer invisible:
	repeat with win_layer from (count win_layers) to 1 by -1
		set thisLayer to item win_layer of win_layers
		if win_layer = (count win_layers) then
		else
			set visible of thisLayer to false
		end if
	end repeat
	
	-- Now, let's switch them on - one after another - and
	-- create a PNG out of the result:
	repeat with win_layer from (count win_layers) to 1 by -1
		set thisLayer to item win_layer of win_layers
		set visible of thisLayer to true
		set thisCount to thisCount + 1
		set targetFile to (thisDocument's path & "-" & canvasName & "-" & thisCount & ".png")
		save thisDocument as "PNG" in POSIX file targetFile
	end repeat
end tell