sed script for updating a variable in place or appending it to an existing .env file

sed-update-env.sh

# Script for updating a var in an .env file
# (will add it to the end of the file, if not found)
sed -in '
# If a line contains our variable, continue at :set
s/^ENV_VAR=.*$//; t set
# Otherwise if this is the last line, check the hold space
# If hold space is empty, no substitution occured, we need
# to manually add the line at the end of the .env file
$ { x; /^$/ { x; p; b set }; d }
# Just print non-matching lines
p;d
# Reuse the same code to make the change/append the value
:set
# Change current line to updated value
# Store a sentinel value on the hold space to track
# substitution so we skip adding a duplicate line at the end
s/.*/ENV_VAR=newvalue/p; h; d' .env

# sed documentation/resources used:
# - https://www.grymoire.com/unix/Sed.html
# - https://linuxhandbook.com/sed-reference-guide/

Updated script (line #9) to fix the last line being accidentally overwritten when the variable is not already in the file.

thanks for the script, but it doesn't work when .env is empty