gistfile1.txt

pkgname=metasploit-git
pkgver=4.8.0.RC2.2.gf402f4c
pkgrel=1
pkgdesc="An open source platform that supports vulnerability research, exploit development and the creation of custom security tools representing the largest collection of quality-assured exploits"
depends=('ruby' 'libpcap' 'postgresql-libs' 'ruby-msgpack')
arch=('i686' 'x86_64')
optdepends=('java-runtime: msfgui'
            'dradis: dradisis database system'
            'postgresql: database')
makedepends=('git')
url='http://www.metasploit.com'
license=('BSD')
conflicts=('metasploit')
provides=('metasploit')
options=('!strip')
source=('git+https://github.com/rapid7/metasploit-framework')
md5sums=('SKIP')

pkgver () {
  cd "$srcdir/metasploit-framework"
  #_date=`date +"%Y%m%d"`
  #echo "$_date.$(git rev-list --count master).$(git rev-parse --short master)"
  git describe --tags | sed 's/-/./g;s/_/./g'
  #echo "$_date.$(git rev-list --count master).$(git rev-parse --short master)"
}

package() {
  cd "$srcdir/metasploit-framework"

  # Base directories.
  install -dm755 "$pkgdir/usr/bin"
  install -dm755 "$pkgdir/etc"
  install -dm755 "$pkgdir/usr/share/metasploit"
  install -dm755 "$pkgdir/usr/share/doc/metasploit"

  # Shareable.
  cp --no-preserve=ownership -R documentation/* "$pkgdir/usr/share/doc/metasploit"
  cp --no-preserve=ownership README.md "$pkgdir/usr/share/doc/metasploit"

  # Source + Bin.
  git clone "$srcdir/metasploit-framework" "$pkgdir/usr/share/metasploit"
  #cp --no-preserve=ownership -R * "$pkgdir/usr/share/metasploit"
  #rm -rf "$pkgdir/usr/share/metasploit"/{README.md,documentation}

  # Conform to the FHS.
  mv "$pkgdir/usr/share/metasploit/config" "$pkgdir/etc/metasploit"
  ln -s /etc/metasploit "$pkgdir/usr/share/metasploit/config"

  cd "$pkgdir/usr/bin"

  for f in "../share/metasploit/msf*"; do
    ln -s $f .
  done
}