Websocket.fs

module Elmish.WebSocket

open Fable.Core
open Elmish
open Fable.Import.Browser
open Fable.Import.JS
open Fable.Core.JsInterop
open System.Runtime.InteropServices.ComTypes

[<RequireQualifiedAccess>]
type WebSocketMsg<'Data> =
   | Connected
   | Disconnected
   | Error of string
   | Data of 'Data

let createAuthenticated (url:string,jwt:string) = 
    WebSocket.Create(url + sprintf "/token/%s" (encodeURI jwt))

let send (ws:Fable.Import.Browser.WebSocket) msg =
    let m = toJson msg
    ws.send m

module Cmd =
    let [<PassGenerics>] Configure<'Data,'msg> (ws:Fable.Import.Browser.WebSocket) (messageCtor:WebSocketMsg<'Data> -> 'msg) =
        let configure dispatch =
            ws.onmessage <- 
                unbox (fun (msg: MessageEvent) ->
                        let msg' = msg.data |> string
                        let decoded = msg' |> ofJson<'Data>
                        dispatch (messageCtor (WebSocketMsg.Data decoded))
                        unbox None)
            ws.onopen <- unbox (fun _ -> dispatch (messageCtor WebSocketMsg.Connected))
            ws.onclose <- unbox (fun _ -> dispatch (messageCtor WebSocketMsg.Disconnected))
            ws.onerror <- unbox (fun evt-> dispatch (messageCtor (WebSocketMsg.Error (unbox evt?data))))
            ()

        [configure]