This script will create a new notebook for a new writing project and create a pre-set collection of blank notes for that project. Currently, the script creates notebooks aimed at academic writing projects.

Create Writing Project Template Notebook

property tb : ASCII character 9
property LF : ASCII character 10

tell application "Evernote"
  set theQuery to display dialog "What is the title of your writing project?" with title "Project Notebook Template" default answer ""
	set projectName to "@" & text returned of theQuery
	if (not (notebook named projectName exists)) then
		set nb to make notebook with properties {name:projectName}
	else
		set nb to notebook projectName
	end if
	
	set theTags to {"outline", "source notes", "bib", "index", "draft"}
	repeat with i from 1 to count of theTags
		set theTag to item i of theTags
		if (not (tag named theTag exists)) then
			make tag with properties {name:theTag}
		end if
	end repeat
	
	set Otag to tag "outline"
	set Ntag to tag "source notes"
	set Btag to tag "bib"
	set Itag to tag "index"
	set Dtag to tag "draft"
	
	set outlineNote to create note title "! Outline" with text "[This is the backbone of a sample outline]" & LF & LF & "[HINT: Use the \"Outline to Evernote\" script to create the corresponding notes for your outline]" & LF & LF & "1. " & LF & tb & "1.1 " & LF & tb & tb & "1.1.1 " & LF & tb & "1.2 " & LF & tb & tb & "1.2.1 " & LF & tb & "1.3 " & LF & LF & "2. " & LF & tb & "2.1 " & LF & tb & tb & "2.1.1 " & LF & tb & "2.2 " & LF & tb & tb & "2.2.1 " & LF & tb & "2.3 " & LF & LF & "3. " & LF & tb & "3.1 " & LF & tb & tb & "3.1.1 " & LF & tb & "3.2 " & LF & tb & tb & "3.2.1 " & LF & tb & "3.3 " & LF & LF notebook nb
	set draftNote to create note title "! Draft" with text "[Your drafts go here]" notebook nb
	set tocNote to create note title "! ToC" with text "[Your Table of Contents for this Project goes here]" & LF & LF & "[HINT: Use the \"Create Notebook Index Note\" script for this note]" notebook nb
	set bibNote to create note title "! Bibliography" with text "[Your bibliography goes here]" & LF & LF & "Primary Sources:" & LF & LF & LF & "Secondary Sources:" notebook nb
	set sourceNote1 to create note title "# Comment" with text "[Your comments and notes on a particular source go here]" notebook nb
	
	assign Otag to outlineNote
	assign Dtag to draftNote
	assign Itag to tocNote
	assign Btag to bibNote
	assign {Btag, Ntag} to sourceNote1
end tell