Visualising package dependencies in Squeak

dotify-package-deps.st

| allDeps toDigraph |
toDigraph := [:hash | | s |
	s := WriteStream on: String new.
	s nextPutAll: 'digraph {'; lf.
	hash keysAndValuesDo: [:pkg :pkgDeps |
		pkgDeps do: [:dep |
			(pkg includesSubString: 'Test')
				ifTrue: [s nextPutAll: '  "'; nextPutAll: pkg; nextPutAll: '" [color="gray"]'; lf].
			s nextPutAll: '  "'; nextPutAll: pkg; nextPutAll: '" -> "'; nextPutAll: dep; nextPutAll: '"'.
			(pkg includesSubString: 'Test') ifTrue: [s nextPutAll: ' [color="gray"]'].
			s lf]].
	s nextPutAll: '}'.
	s contents].

allDeps := Dictionary new.
DependencyBrowser new in: [:dep|
	PackageInfo allPackages do: [:p | | depClasses |
		dep computePackageDependencies: p name.
		depClasses := (dep instVarNamed: 'classDeps') keys intersection: (p classes collect: #name).
		allDeps at: p name put: (dep packageDeps)]].

FileStream fileNamed: 'c:\users\frank\squeak-ci\trunkimage-deps.dot' do: [:f |
	f nextPutAll: (toDigraph value: allDeps)].

To display the graph, install graphviz and run

dot -Tpng -o output.png thedotfile.dot

(from http://forum.world.st/Byte-1981-online-version-tp4723846p4723918.html )