workflow library

Workflow.hs

{-# LANGUAGE KindSignatures #-}

module Workflow where

import Data.Bool (bool)


data Workflow a r
  = Decision a (Workflow a r) (Workflow a r)
  | Guard a (Workflow a r)
  | Activity a (Workflow a r)
  | Conclusion a r

-- | Output from guard step.  Either stop and return a result,
-- or keep going with the next step.
data Guard r = Stop r | KeepGoing


runWorkflow
  :: (Monad m)
  => (a -> m Bool)      -- execute decision
  -> (a -> m (Guard r)) -- execute guard
  -> (a -> m ())        -- execute activity
  -> (a -> r -> m ())   -- execute conclusion
  -> Workflow a r
  -> m r
runWorkflow fd fg fa fc workflow =
  let
    go = runWorkflow fd fg fa fc
  in
    case workflow of
      Decision desc t f ->
        fd desc >>= go . bool f t
      Guard desc next ->
        fg desc >>= \g -> case g of
          KeepGoing -> go next
          Stop r -> pure r
      Activity desc next ->
        fa desc *> go next
      Conclusion desc r ->
        r <$ fc desc r