vapoursynth-plugin-eedi3cl-git meson/ninja PKGBUILD

PKGBUILD

# Maintainer:  Gustavo Alvarez <[email protected]>

_plug=eedi3cl
pkgname=vapoursynth-plugin-${_plug}-git
pkgver=r4.1.gefcba5f
pkgrel=1
pkgdesc="Plugin for Vapoursynth: ${_plug} (GIT version)"
arch=('i686' 'x86_64')
url='https://github.com/HomeOfVapourSynthEvolution/VapourSynth-EEDI3'
license=('GPL2')
depends=('vapoursynth'
         'ocl-icd'
         )
makedepends=('git'
             'opencl-headers'
             'boost'
             'meson'
             'ninja'
             )
provides=("vapoursynth-plugin-${_plug}")
conflicts=("vapoursynth-plugin-${_plug}"
           'vapoursynth-plugin-eedi3-ocl'
           )
source=("${_plug}::git+https://github.com/HomeOfVapourSynthEvolution/VapourSynth-EEDI3.git")
sha256sums=('SKIP')

pkgver() {
  cd "${_plug}"
  echo "$(git describe --long --tags | tr - .)"
}

build() {
  cd "${_plug}"
  meson build
  ninja -C build  
}

package(){
  cd "${_plug}"
  install -Dm644 README.md "${pkgdir}/usr/share/doc/vapoursynth/plugins/${_plug}/README.md"
  install -Dm755 build/libeedi3m.so "${pkgdir}/usr/lib/vapoursynth/libeedi3m.so"  
}