simple_earthy_code_zsh_prompt

simple_earthy_code_zsh_prompt.sh

#!/bin/sh
#
# A theme based on Steve Losh's Extravagant Prompt with vcs_info integration.
#
# Screenshots:
#   http://i.imgur.com/HyRvv.png

function prompt_simple_earthy_code_precmd {
  # Check for untracked files or updated submodules since vcs_info does not.
  if [[ -n $(git ls-files --other --exclude-standard 2> /dev/null) ]]; then
    branch_format="(${_prompt_simple_earthy_code_colors[1]}%b%f%u%c${_prompt_simple_earthy_code_colors[4]}●%f)"
  else
    branch_format="(${_prompt_simple_earthy_code_colors[1]}%b%f%u%c)"
  fi

  zstyle ':vcs_info:*:prompt:*' formats "${branch_format}"

  vcs_info 'prompt'

  _prompt_pwd=$(prompt-pwd)

  if (( $+functions[python-info] )); then
    python-info
  fi
}

function prompt_simple_earthy_code_setup {
  setopt LOCAL_OPTIONS
  unsetopt XTRACE KSH_ARRAYS
  prompt_opts=(cr percent sp subst)

  # Load required functions.
  autoload -Uz add-zsh-hook
  autoload -Uz vcs_info

  # Add hook for calling vcs_info before each command.
  add-zsh-hook precmd prompt_simple_earthy_code_precmd

  # Use extended color pallete if available.
  if [[ $TERM = *256color* || $TERM = *rxvt* ]]; then
    _prompt_simple_earthy_code_colors=(
      "%F{81}"  # Turquoise
      "%F{166}" # Orange
      "%F{135}" # Purple
      "%F{161}" # Hotpink
      "%F{118}" # Limegreen
    )
  else
    _prompt_simple_earthy_code_colors=(
      "%F{cyan}"
      "%F{yellow}"
      "%F{magenta}"
      "%F{red}"
      "%F{green}"
    )
  fi

  # Formats:
  #   %b - branchname
  #   %u - unstagedstr (see below)
  #   %c - stagedstr (see below)
  #   %a - action (e.g. rebase-i)
  #   %R - repository path
  #   %S - path in the repository
  local branch_format="(${_prompt_simple_earthy_code_colors[1]}%b%f%u%c)"
  local action_format="(${_prompt_simple_earthy_code_colors[5]}%a%f)"
  local unstaged_format="${_prompt_simple_earthy_code_colors[2]}●%f"
  local staged_format="${_prompt_simple_earthy_code_colors[5]}●%f"

  # Set vcs_info parameters.
  zstyle ':vcs_info:*' enable git
  zstyle ':vcs_info:*:prompt:*' check-for-changes true
  zstyle ':vcs_info:*:prompt:*' unstagedstr "${unstaged_format}"
  zstyle ':vcs_info:*:prompt:*' stagedstr "${staged_format}"
  zstyle ':vcs_info:*:prompt:*' actionformats "${branch_format}${action_format}"
  zstyle ':vcs_info:*:prompt:*' formats "${branch_format}"
  zstyle ':vcs_info:*:prompt:*' nvcsformats   ""

  # Set python-info parameters.
  zstyle ':prezto:module:python:info:virtualenv' format '(%v)'

  _prompt_pwd=''

  # Define prompts.
  PROMPT="${_prompt_simple_earthy_code_colors[5]}%2~%f "'${vcs_info_msg_0_}''$python_info[virtualenv]'"$ "
  RPROMPT=''
}

prompt_simple_earthy_code_setup "$@"