AspectJ for Java in Gradle 6.3

aspectj.gradle

buildscript {
    ext {
        aspectjVersion = '1.9.5'
        springVersion = '5.1.11.RELEASE'
    }
}

apply plugin: 'java'

configurations {
    ajc
    aspects
    compile {
        extendsFrom aspects
    }
}

dependencies {
    compile "org.aspectj:aspectjrt:${aspectjVersion}"
    compile "org.aspectj:aspectjweaver:${aspectjVersion}"

    ajc "org.aspectj:aspectjtools:${aspectjVersion}"
    aspects "org.springframework:spring-aspects:${springVersion}"
}

def aspectj = { destDir, aspectPath, inpath, classpath ->
    ant.taskdef(resource: "org/aspectj/tools/ant/taskdefs/aspectjTaskdefs.properties",
            classpath: configurations.ajc.asPath)

    ant.iajc(
            maxmem: "1024m", fork: "true", Xlint: "ignore",
            destDir: destDir,
            aspectPath: aspectPath,
            inpath: inpath,
            classpath: classpath,
            source: project.sourceCompatibility,
            target: project.targetCompatibility
    )
}

compileJava {
    doLast {
        aspectj project.sourceSets.main.output.classesDirs.asPath,
                configurations.aspects.asPath,
                project.sourceSets.main.output.classesDirs.asPath,
                project.sourceSets.main.runtimeClasspath.asPath
    }
}

compileTestJava {
    dependsOn jar

    doLast {
        aspectj project.sourceSets.test.output.classesDirs.asPath,
                configurations.aspects.asPath + jar.archiveFile,
                project.sourceSets.test.output.classesDirs.asPath,
                project.sourceSets.test.runtimeClasspath.asPath
    }
}