UDP and HTTP server in Ren-c

a1.reb

Rebol [
	file: %a1.reb
	notes: {ssdp with http server in ren-c

		httpd.reb is here https://gist.github.com/rgchris/73510e7d643eb0a6b9fa69b849cd9880
	}
]

serve-udp: open udp://:1900

serve-udp/awake: func [evt][ 
	print ["multicast event:" evt/type " on " evt/port/spec/port-id " at " now/precise]

	switch/default evt/type [ 
		read [ 
			print ["read server data:" newline to-string evt/port/data] 
			; process UDP notifications here
			clear evt/port/data 
			; keep reading the port and not exit the awake function
			read evt/port
			; return true 
		]
		error [
			; do we need to exit on error?
			return false
		]
	][ return false]
] 

set-udp-multicast serve-udp 239.255.255.250 0.0.0.0 
set-udp-ttl serve-udp 1

do %httpd.reb

serve-http: open [
    Scheme: 'httpd
    Port-ID: 8001
    Awake: func [
        request [object!]
    ][
    	print ["http request at " now/precise]
    	; process all http events here, eg.
        make object! compose [
            Status: 200
            Type: "text/html"
            Content: reword "<h1>OK! $action :: $target</h1>" compose [
                action (request/action)
                target (request/target)
            ]
        ]
    ]
]

wait-ports: copy []
append wait-ports serve-http
append wait-ports serve-udp

attempt [browse http://127.0.0.1:8001/try/this/path]

print "Listening ..."
read serve-udp ; seems to be necessary
forever [
	print ["start wait at " now/precise]
	wait wait-ports
]

By not exiting the serve-udp awake function, we can take the read serve-udp out of the forever loop.