New Repo, Initial Commit from Local (Windows/Not Windows)

_NEWREPO.md

newrepo

Intro

This utility is for creating a new GitHub repo from the command line. I made these because a lot of the time, I have to do things locally and then figure out getting the repo made and synced, etc. Now, I am (and by extension you are) capable of just creating a new repo from content that already exists in a directory.

You do need to have at least one file in the directory to commit. It will always commit with the comment Initial commit, unless of course you change it. Which you can... well, you may, idk if you can, that's not really on me, is it? Nope. Not even a little bit. Change or no change or whatever. idc 🤷🏻‍♂️

Also, you need to have GitHub CLI installed.

Windows

1. Copy the newrepo.cmd file to a location in your PATH

Not Windows

1. Copy the newrepo.sh file to a location in your PATH (maybe even remove the .sh file ending?)
2. Make it executable: chmod +x newrepo.sh

Finally

In a new directory, type: newrepo [reponame]

The reponame argument is optional. If not provided, it will use the cwd as the repo name.

newrepo.cmd

@echo off

REM Ensure GitHub CLI is installed
where gh >nul 2>nul
if %errorlevel% neq 0 (
    echo Error: GitHub CLI ^(gh^) is not installed. Install it first: https://cli.github.com/
    exit /b 1
)

REM Set repo name to current directory if not provided
set "REPO_NAME=%~1"
if "%REPO_NAME%"=="" (
    for %%i in ("%cd%") do set "REPO_NAME=%%~nxi"
)

REM Check if repo name is valid
if "%REPO_NAME%"=="" (
    echo Error: Unable to determine repository name.
    exit /b 1
)

REM Check if .git directory exists
if not exist .git (
    git init
    if %errorlevel% neq 0 (
        exit /b 1
    )
)

REM Create Initial Commit
git add .
if %errorlevel% neq 0 (
    exit /b 1
)
git commit -m "Initial commit"
if %errorlevel% neq 0 (
    exit /b 1
)

REM Create GitHub Repository
gh repo create "%REPO_NAME%" --public --source=. --remote=origin
if %errorlevel% neq 0 (
    exit /b 1
)

REM Push Changes
git push -u origin main
if %errorlevel% neq 0 (
    exit /b 1
)
echo Repository "%REPO_NAME%" created and pushed successfully!

newrepo.sh

#!/bin/bash

# Ensure GitHub CLI is installed
if ! command -v gh &> /dev/null; then
    echo "Error: GitHub CLI (gh) is not installed. Install it first: https://cli.github.com/"
    exit 1
fi

# Set repo name to current directory if not provided
REPO_NAME="${1:-$(basename "$PWD")}"

# Check if repo name is valid
if [ -z "$REPO_NAME" ]; then
    echo "Error: Unable to determine repository name."
    exit 1
fi

# Check if .git directory exists
if [ ! -d ".git" ]; then
    git init
    if [ $? -ne 0 ]; then
        exit 1
    fi
fi

# Create Initial Commit
git add .
if [ $? -ne 0 ]; then
    exit 1
fi
git commit -m "Initial commit"
if [ $? -ne 0 ]; then
    exit 1
fi

# Create GitHub Repository
gh repo create "$REPO_NAME" --public --source=. --remote=origin
if [ $? -ne 0 ]; then
    exit 1
fi

# Push Changes
git push -u origin main
if [ $? -ne 0 ]; then
    exit 1
fi
echo "Repository \"$REPO_NAME\" created and pushed successfully!"