Variant aware dependency management

build.gradle

// Declare a new attribute type to use for selection
def usageAttribute = Attribute.of("com.adyen.usage", String)
// In both the producer and consumer, register the new attribute and set
// up a configuration associated to the attribute
subprojects {
    dependencies.attributesSchema {
        attribute(usageAttribute)
    }
    configurations { 
        web {
            attributes {
                attribute(usageAttribute, "web-resource") 
            }
        }
    }
}

project(':web-resources') {
    apply plugin: 'java'

    task webZip(type: Zip) {
        from 'resources'
        classifier 'web'
    }

    // Associate an artifact with the configuration
    artifacts {
        web webZip
    }
}

project(':war') {
    apply plugin: 'java'

    dependencies {
        // declare a dependency on the project in the configuration with the 
        // appropriate attribute
        web project(':web-resources')
    }

    task copyWeb(type: Copy) {
        from configurations.web
        into layout.buildDir.dir('resources')
    }
}