Open four tabs into a project directory

iTerm four tabs.applescript

-- Set the directory where your projects live
set projectsDirectory to ((path to home folder) as string) & "projects:"

-- Set your editor command
set editorCommand to "mvim"

-- Set your default session name here
set defaultSession to "Default"

tell me
  activate
end tell

set project to text returned of (display dialog "Project directory" default answer "")

if project is "" then
  display dialog "You didn't give a project"
  return
end if

try
  set projectPath to projectsDirectory & project as alias
on error
  display dialog "That project doesn't exist"
  return
end try

tell application "iTerm"
  tell (make new terminal)
    repeat with i from 1 to 4 by 1
      launch session defaultSession
      tell the last session
        set name to project
        write text "cd " & POSIX path of projectPath
        if i is 1 then
          write text "echo -e \"\\033]\" & project & \"\\007\""
          write text editorCommand
        end if
        write text "clear"
        if i is 4 then
          write text "vagrant up"
        end if
      end tell
    end repeat
  end tell
end tell