c64os_prg_7_bg.asm

msgcmd   ;A -> Message Code
         .block
         #switch 6
         .byte mc_menq,mc_mnu,mc_stptr
         .byte mc_col,mc_rflg,mc_theme

         .rta menuenq,menucmd,statptr
         .rta colorset,rflags,cthem

         sec      ;Message Not Supported
         rts

statptr  ;RegPtr <- Status String
         ;C Clr  <- Custom Status Avail.
         #ldxy statline
         clc
         rts

statline .text " TestGround         "
         .text "  Gregory Nacu "
         .byte $b0
         .null "2021"

colorset ;X -> Color Code
         txa
         pha

         #storeget views,2 ;Right Cntent
         jsr ptrthis

         pla
         ldy #bcolor
         sta (this),y
         sta brdrcol       ;State config

         jsr thisdirt
         jmp mkdirt

rflags   ;Redraw Flags Changed.
         #rdxy tkenv+te_rview
         jsr ptrthis

         ldy #offtop
         lda redrawflgs
         and #rmenubar
         beq *+4
         lda #1
         sta (this),y

         ldy #offbot
         lda redrawflgs
         and #rstatbar
         beq *+4
         lda #1
         sta (this),y

         #setflag this,mflags,mf_resiz
         bne mkdirt

cthem    #rdxy tkenv+te_rview
         jsr ptrthis

         jsr thisdirt
         bne mkdirt
         .bend