c64os_prg_7_bi.asm

menucmd  ;X -> Menu Command Code
         .block
         txa
         #switch 8
         .text "khls!ewf"
         .rta a_killmus,a_hidemus
         .rta a_loadmus,a_showmus
         .rta quitapp
         .rta a_raise
         .rta a_togwrap,a_togfoot

         ;Change Current Tab
         cmp #"4"
         bcs done ;>"3"
         cmp #"1"
         bcc done ;<"1"

         ;C <- SET
         sbc #"1"  ;"1" -> 0... "3" -> 2
         cmp seltab
         bne *+4

         clc ;Handled, selected already.
done     rts

         pha ;new tab index

         #ldxy tkenv
         jsr settkenv

         #storeget views,3 ;TKTabs
         jsr ptrthis

         ldy #seltab_
         jsr getmethod

         pla ;new tab index
         jsr sysjmp
         jmp mkdirt

a_killmus
         jsr killmouse
         clc        ;Menu Action Handled
         rts

a_hidemus
         jsr hidemouse
         clc        ;Menu Action Handled
         rts

a_loadmus
         clc              ;Disk Load
         bcc *+3
a_showmus
         sec              ;Skip Load
         jsr initmouse
         clc        ;Menu Action Handled
         rts

a_raise  jsr exception
         .bend