Code listings (legacy XML Schema) for "An intro to using match templates in Umbraco" (Pimp My XSLT article)

match-templates-intro-01_legacy.xslt

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE xsl:stylesheet [ <!ENTITY nbsp "&#x00A0;"> ]>
<xsl:stylesheet 
    version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:msxml="urn:schemas-microsoft-com:xslt" 
    xmlns:umbraco.library="urn:umbraco.library"
    exclude-result-prefixes="msxml umbraco.library">

<xsl:output method="xml" omit-xml-declaration="yes"/>

<xsl:param name="currentPage"/>

<xsl:template match="/">

<!-- The fun starts here -->
<ul>
<xsl:for-each select="$currentPage/node [string(data [@alias = 'umbracoNaviHide]) != '1']">
    <li>
        <a href="{umbraco.library:NiceUrl(@id)}">
            <xsl:value-of select="@nodeName"/>
        </a>
    </li>
</xsl:for-each>
</ul>

</xsl:template>

</xsl:stylesheet>

match-templates-intro-02_legacy.xslt

<xsl:template match="/">
    <ul>
        <xsl:apply-templates select="$currentPage/node [string(data [@alias = 'umbracoNaviHide]) != '1']" />
    </ul>
</xsl:template>

<xsl:template match="node">
    <li>
        <a href="{umbraco.library:NiceUrl(@id)}">
            <xsl:value-of select="@nodeName" />
        </a>
    </li>
</xsl:template>

match-templates-intro-03_legacy.xslt

<xsl:template match="/">
    <ul>
        <xsl:apply-templates select="$currentPage/node" />
    </ul>
</xsl:template>

<xsl:template match="node">
    <li>
        <a href="{umbraco.library:NiceUrl(@id)}">
            <xsl:value-of select="@nodeName" />
        </a>
    </li>
</xsl:template>

<xsl:template match="node[data[@alias = 'umbracoNaviHide'] = 1]" />

match-templates-intro-04_legacy.xslt

<xsl:template match="/">
    <xsl:apply-templates select="$currentPage" />
</xsl:template>

<xsl:template match="node[@nodeTypeAlias = 'News'] | node[@nodeTypeAlias = 'Events']">
    <h2>
        <xsl:value-of select="@nodeTypeAlias" />
    </h2>
    <ul>
        <xsl:apply-templates select="node[@nodeTypeAlias = 'NewsItem'] | node[@nodeTypeAlias = 'Event']" />
    </ul>
</xsl:template> 

<xsl:template match="node[@nodeTypeAlias = 'NewsItem'] | node[@nodeTypeAlias = 'Event']">
    <li>
        <a href="{umbraco.library:NiceUrl(@id)}">
            <xsl:value-of select="@nodeName" />
        </a>
    </li>
</xsl:template>

<xsl:template match="node[data[@alias = 'umbracoNaviHide'] = 1]" />

match-templates-intro-05_legacy.xslt

<xsl:template match="/">
    <xsl:apply-templates select="$currentPage/ancestor-or-self::node[@nodeTypeAlias = 'News' or @nodeTypeAlias = 'Events']" />
</xsl:template>

match-templates-intro-06_legacy.xslt

<xsl:template match="node[@nodeTypeAlias = 'News'] | node[@nodeTypeAlias = 'Events']">
    <h2>
        <xsl:value-of select="@nodeTypeAlias" />
    </h2>
    <ul id="{translate(@nodeTypeAlias, 'NE', 'ne')}">
        <xsl:apply-templates select="node[@nodeTypeAlias = 'NewsItem'] | node[@nodeTypeAlias = 'Event']" />
    </ul>
</xsl:template>

<xsl:template match="node[@nodeTypeAlias = 'NewsItem'] | node[@nodeTypeAlias = 'Event']">
    <li>
        <xsl:if test="@id = $currentPage/@id"><xsl:attribute name="class">selected</xsl:attribute></xsl:if>
        <a href="{umbraco.library:NiceUrl(@id)}">
            <xsl:value-of select="@nodeName" />
        </a>
    </li>
</xsl:template>

match-templates-intro-07_legacy.xslt

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE xsl:stylesheet [ <!ENTITY nbsp "&#x00A0;"> ]>
<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:umbraco.library="urn:umbraco.library"
    exclude-result-prefixes="umbraco.library">

    <xsl:output method="xml" omit-xml-declaration="yes" indent="yes" />

    <xsl:param name="currentPage" />

    <xsl:template match="/">
        <xsl:apply-templates select="$currentPage/ancestor-or-self::node[@nodeTypeAlias = 'News' or @nodeTypeAlias = 'Events']" />
    </xsl:template>

    <xsl:template match="node[@nodeTypeAlias = 'News'] | node[@nodeTypeAlias = 'Events']">
        <h2>
            <xsl:value-of select="@nodeTypeAlias" />
        </h2>
        <ul id="{translate(@nodeTypeAlias, 'NE', 'ne')}">
            <xsl:apply-templates select="node[@nodeTypeAlias = 'NewsItem'] | node[@nodeTypeAlias = 'Event']" />
        </ul>
    </xsl:template>

    <xsl:template match="node[@nodeTypeAlias = 'NewsItem'] | node[@nodeTypeAlias = 'Event']">
        <li>
            <xsl:if test="@id = $currentPage/@id"><xsl:attribute name="class">selected</xsl:attribute></xsl:if>
            <a href="{umbraco.library:NiceUrl(@id)}">
                <xsl:value-of select="@nodeName" />
            </a>
        </li>
    </xsl:template>

    <xsl:template match="node[data[@alias = 'umbracoNaviHide'] = 1]" />

</xsl:stylesheet>