Arch Linux PKGBUILD for telxcc (https://github.com/forers/telxcc)

PKGBUILD

# Maintainer: kfgz <kfgz at interia dot pl>
# Contributor: Gustavo Alvarez <sl1pkn07 at gmail dot com>
# Contributor: Konstantin Gribov <grossws at gmail dot com>

pkgname=telxcc-git
pkgver=2.5.3.r3.g2f90d0b
pkgrel=1
pkgdesc="TELeteXt Closed Captions decoder (produces subtitles in .SRT format from transport stream .TS files) (GIT version)"
arch=('i686' 'x86_64')
url="https://github.com/forers/telxcc"
license=('custom:Forers')
conflicts=('telxcc')
provides=('telxcc')
source=('git://github.com/forers/telxcc.git')
md5sums=('SKIP')
makedepends=('git')
_gitname="telxcc"

pkgver() {
  cd "${_gitname}"
  git describe --long --tags | sed -r 's/^v//;s/([^-]*-g)/r\1/;s/-/./g'
}

build() {
  cd "${_gitname}"
  
  if [ "${CARCH}" = "x86_64" ]; then
   gcc -m64 -march=x86-64 -mtune=generic -O2 -pipe -Wall -std=gnu99 -pedantic -fstack-protector --param=ssp-buffer-size=4 telxcc.c -o telxcc
  else
   gcc -m32 -march=i686 -mtune=generic -O2 -pipe -Wall -std=gnu99 -pedantic -fstack-protector --param=ssp-buffer-size=4 telxcc.c  -o telxcc
  fi
  
  make man
}

package() {
  cd "${_gitname}"
  install -Dm755 telxcc "${pkgdir}/usr/bin/telxcc"
  install -Dm644 telxcc.1.gz "${pkgdir}/usr/share/man/man1/telxcc.1.gz"
  install -Dm644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}