Using the Maybe monad in hypothetical Ring middleware

maybe_monad.clj

(ns maybe-monad
  (:require [clojure.algo.monads :refer [domonad maybe-m]]
            [myapp.magic :as magic]))

;; Non-monadic version

(defn wrap-user
  "Add user information to the request map if logged in."
  [handler]
  (fn [request]
    (let [db (get-in request [:myapp :system :db])
          ident (get-in request [:session ::friend/identity :current])]
      (if ident
        (let [user (magic/user-by-id db ident)]
          (if user
            (handler (assoc-in request [:myapp :user] user))
            (handler request)))
        (handler request)))))

;; Monadic version

(defn wrap-user
  "Add user information to the request map if logged in."
  [handler]
  (fn [request]
    (let [db (get-in request [:myapp :system :db])
          user (domonad maybe-m [ident (get-in request [:session ::friend/identity :current])
                                 u (magic/user-by-id db ident)]
                 u)]
      (if user
        (handler (assoc-in request [:myapp :user] user))
        (handler request)))))

;; Shorter monadic version

(defn wrap-user
  "Add user information to the request map if logged in."
  [handler]
  (fn [request]
    (let [db (get-in request [:myapp :system :db])
          user (domonad maybe-m [ident (get-in request [:session ::friend/identity :current])]
                 (magic/user-by-id db ident))]
      (if user
        (handler (assoc-in request [:myapp :user] user))
        (handler request)))))

;; The main benefit is that (handler request) does not need to be duplicated for each
;; new piece of logic we may want to add.