podman-compose-git PKGBUILD

PKGBUILD

pkgname=podman-compose-git
pkgver=1.5.0
pkgrel=3
epoch=1
pkgdesc="A script to run docker-compose.yml using podman"
arch=('any')
url="https://github.com/containers/podman-compose"
license=('GPL2')
depends=(
  podman
  python
  python-dotenv
  python-yaml
)
makedepends=(
  python-build
  python-installer
  python-setuptools
  python-wheel
)
checkdepends=(
  python-pytest
  python-parameterized
)
optdepends=('podman-dnsname: the containers will be able to resolve each other if they are on the same CNI network')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("${pkgname%-git}::git+https://github.com/containers/podman-compose")
sha256sums=('SKIP')

pkgver() {
  cd "${srcdir}/${pkgname%-git}"
  # Alt. way of getting version number:
  printf "$(python -c 'from podman_compose import __version__; print(__version__)')"
}

build() {
  cd "${srcdir}/${pkgname%-git}"
  python -m build --wheel --no-isolation
}

package() {
  cd "${srcdir}/${pkgname%-git}"
  python -m installer --destdir="$pkgdir" dist/*.whl
  find examples -type f -exec install -vDm 644 {} "$pkgdir/usr/share/doc/$pkgname/"{} \;
  install -vDm 644 {README.md,docs/*} -t "$pkgdir/usr/share/doc/$pkgname/"
}

# vim: set et ts=2 sw=2:

Extremely hacked PKGBUILD to install latest podman-compose from git.

Original podman-compose-git seems unmaintained.

This is offered with no warranty or support, YMMV.