Record Visitor Pattern

record_visitor.bal

import ballerina/io;

// Type Nodes

type Node record {
    string kind;
    string value;
};

type NodeA record {
    *Node;
    "NodeA" kind = "NodeA";
    string value;
};

type NodeB record {
    *Node;
    "NodeB" kind = "NodeB";
    string value;
    int count;
};

// Actual Node vistor Logic

function visitNodeA(NodeA node) {
    io:println("Do something with NodeA", node);
}

function visitNodeB(NodeB node) {
    io:println("Do something with NodeB", node);
}

// Node visitor dispatcher

function visit(Node node) returns error? {
    match node.kind {
        "NodeA" => {
            visitNodeA(check node.ensureType());
        }
        "NodeB" => {
            visitNodeB(check node.ensureType());
        }
    }
}

public function main() returns error? {
    Node[] nodes = [
        {kind: "NodeA", value: "A"},
        {kind: "NodeB", value: "B", "count": 1},
        {kind: "NodeA", value: "C"}
    ];

    foreach var node in nodes {
        check visit(node);
    }
}