`ppp` is a zsh script for inspecting basic filename whitespace

ppp

#!/usr/bin/env -S zsh -e

help() {
  print -u2 -- "Usage: $ZSH_ARGZERO [options] [directory...]

Options:
    -h, --help     Output this help message
    -v, --version  Output program name and version"
    exit ${1:-0}
}

version() {
  print -- "ppp $1"
  exit 0
}

not_a_dir_error() {
  print -ru2 -- "$ZSH_ARGZERO: $1: Not a directory"
  exit 1
}

pushd_error() {
  print -ru2 -- "$ZSH_ARGZERO: $1: Failed to change directory"
  exit 2
}

zparseopts -D -F -K -- \
  h=h_flag -help=h_flag \
  v=v_flag -version=v_flag \
  || { \help 1 }

(( $#h_flag )) && { \help }
(( $#v_flag )) && { \version "0.0.1" }

(( $# == 0 )) && dirs=( $PWD ) || dirs=( "$@" )

integer index=0
for dir in $dirs; do
  (( $#dirs > 1 )) && (( index > 0 )) && print

  [[ ! -d $dir ]] && { \not_a_dir_error "$dir" }

  if (( $#dirs > 1 )) && print "$dir:"
  (( index+=1 ))

  pushd -q -- $dir || { \pushd_error "$dir" }

  files=( *(N) )

  for file in "${files[@]}"; do
    file=${file// /·}
    file=${file//$'\t'/→}
    file=${file//$'\n'/↵}
    file=${file//$'\r'/↩︎}

    print -r -- "${file}¬"
  done

  popd -q
done