Return a value for an expression passed into a macro, even if that expression references other variables (so long as those variables are declared with inline). Originally from this thread https://community.haxe.org/t/macro-constant-arg-inline-final/3007

EvalConstExpr.hx

/**
 Return a value for an expression passed into a macro, even if that expression references other variables (so long as those variables are declared with inline)
**/
function evalConstExpr(x: Expr) {
	return try {
		ExprTools.getValue(Context.getTypedExpr(Context.typeExpr(x)));
	} catch (e) {
		Context.error("Must be a constant expression (i.e. and expression containing only constants or variables declared with `inline`", x.pos);
	}
}

Example

#if macro
import haxe.io.Path;
import haxe.macro.Context;
import haxe.macro.Expr;
import haxe.macro.ExprTools;
import sys.FileSystem;
import sys.io.File;
#end

macro function embedDirectory(pathExpr: ExprOf<String>) {
	function evalConstExpr(x: Expr) {
		return try {
			ExprTools.getValue(Context.getTypedExpr(Context.typeExpr(x)));
		} catch (e) {
			Context.error("Must be a constant expression (i.e. and expression containing only constants or variables declared with `inline`", x.pos);
		}
	}

	var path = evalConstExpr(pathExpr);

	for (name in FileSystem.readDirectory(path)) {
		var filePath = Path.join([path, name]);
		var bytes = File.getBytes(filePath);
		Context.addResource(filePath, bytes);
	}
	return macro null;
}

inline final iconDirectory = 'Icons';
...
Assets.embedDirectory(iconDirectory);