Cruel Cannon, a hangman type game for the C64 written in BASIC, circa 1993

CRUEL CANNON.PRG

    0 poke808,225:gosub 31000
    1 poke53269,0
   10 remifa=0thena=1:load"c.font3",8,1
   20 remifa=1thena=2:load"lespirites",8,1
  900 ww=68:dim n(ww):dim keer$(50)
 1000 rem *** the game ***
 1010 rem ** after a game over **
 1015 poke 53265,peek(53265) and 239
 1020 sc=0:gd=0:ft=0:ln=0:l$="":w$="":keer=1:keer$(0)="":keer$(1)=""
 1030 gosub 20000:gosub 10000:jaja=0
 1040 gosub 21000:gosub 11000
 1050 poke 53265,peek(53265) or 16
 1100 rem ** the playing **
 1110 restore
 1120 x=int(rnd(0)*ww)+1
 1130 if n(x)=1 then 1120
 1140 n(x)=1
 1150 fort=1tox:readw$:nextt
 1160 ged=0:fout=0
 1170 l=len(w$):z$=w$
 1180 print"{home}{blk}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}";
 1190 fort=1tol:printtab((40-l)/2)"{rvon}3{down}{left}2{up}{rvof}";:next
 1191 remprint"{down}";:fort=1tol:printtab((40-l)/2)"{rvon}2{rvof}";:next
 1195 l$=""
 1200 getl$:ifl$<>""then1200
 1210 getl$:ifl$=""then1210
 1212 kk=asc(l$):if kk<65 or kk>90 then 1200
 1215 keer=keer+1:keer$(keer)=l$:gosub 22000
 1217 if vraag=1 then vraag=0:goto 1200
 1220 hebbes=0
 1230 fort=1tol
 1240 ifl$=mid$(w$,t,1)thengosub3000:hebbes=1
 1250 nextt
 1260 ifhebbes=1 then 1300
 1270 fout=fout+1:gosub 19000:gosub23000
 1280 on fout gosub 12000,13000,14000,15000,16000,17000,18000
 1290 if fout=7 then 4000
 1300 if ged=l then 3100
 1310 goto 1200
 3000 ged=ged+1:l1=asc(l$):l2=l1+97-65
 3010 print"{home}{wht}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}":print tab(((40-l)/2)+t-1);"{rvon}"l$"{rvof}";
 3015 printtab(((120-l)/2)+t-1);"{yel}{rvon}"chr$(l2)"{rvof}"
 3020 return
 3100 sc=sc+100:fort=0 to keer+1:keer$(t)="":next t:goto 1030
 4000 print"{home}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{orng}ABBBBBBBBBBBH"
 4005 print"{up}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{orng}C {wht}{rvon}game{$a0}over{rvof}{orng} G"
 4010 print"{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{orng}C {yel}{rvon}GAME{$a0}OVER{rvof}{orng} G"
 4015 print"{up}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{orng}DEEEEEEEEEEEF"
 4020 geta$:ifa$<>""then4020
 4030 geta$:ifa$=""then4030
 4040 goto 1015
 9999 goto 200
10000 rem *** the screen ***
10001 poke53265,peek(53265) and 239
10005 poke53272,28:printchr$(142)
10010 poke53280,0:poke53281,12
10015 poke53270,24:poke53282,15:poke53283,11
10020 print"{clr}{blu}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{lred}{CBM-T}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-N}{blu}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}"
10025 print"{up}{blu}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{lred}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{blu}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}"
10030 print"{up}{blu}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{lred}{CBM-T}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-N}{blu}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}"
10035 print"{up}{lblu}{CBM-@}{CBM-G}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{lred}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{blu}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}"
10040 print"{up}{lblu}{SHIFT-POUND}{SHIFT-POUND}{CBM-+}{CBM-M}{CBM-POUND}{CBM-G}{SHIFT-*}{SHIFT-*}{SHIFT-*}{lred}{CBM-T}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-N}{lblu}{CBM-G}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}"
10045 print"{up}{lblu}{SHIFT-POUND}{SHIFT-POUND}{SHIFT-POUND}{SHIFT-POUND}{SHIFT-POUND}{SHIFT-POUND}{CBM-+}{CBM-M}{CBM-G}{lred}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{lblu}{SHIFT-POUND}{CBM-+}{CBM-M}{CBM-POUND}{CBM-G}{CBM-@}{CBM-G}{SHIFT-*}{SHIFT-*}"
10050 print"{up}{lblu}{SHIFT-POUND}{SHIFT-POUND}{SHIFT-POUND}{SHIFT-POUND}{SHIFT-POUND}{SHIFT-POUND}{SHIFT-POUND}{SHIFT-POUND}{SHIFT-POUND}{lred}{CBM-T}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-N}{lblu}{SHIFT-POUND}{SHIFT-POUND}{SHIFT-POUND}{SHIFT-POUND}{SHIFT-POUND}{SHIFT-POUND}{SHIFT-POUND}{CBM-+}{SHIFT-*}"
10055 print"{up}{grn}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{lred}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{CBM-K}{CBM-I}{grn}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}"
10060 print"{up}{grn}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{lred}{CBM-K}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{grn}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}"
10065 print"{up}{grn}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{rvon}{orng}_# {rvof}{grn}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}"
10070 print"{up}{grn}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{orng}{CBM-S}{rvon}!{rvof}{CBM-U}{rvon}"chr$(34)chr$(34)"{rvof}{left}{CBM-E}{grn}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}"
10075 print"{up}{grn}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{orng}{CBM-S}{CBM-P}{CBM-A}{CBM-H}{CBM-O}{SHIFT-@}{CBM-F}{CBM-L}{CBM-W}{CBM-R}{CBM-E}{grn}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}{CBM-Q}"
10080 print"{up}{orng}ABBBBBBBBBBBBH{SHIFT-*}{SHIFT-*}{CBM-V}{SHIFT-POUND}{SHIFT-POUND}{SHIFT-+}  {CBM-B}{CBM-Y}{CBM-Y}ABBBBBBBBBBBBBH"
10085 print"{up}C            G{SHIFT-*}{SHIFT-*}{rvon}]{blu}%&'(){orng}^{rvof}{CBM-Y}{CBM-Y}C             G"
10090 print"{up}C ABBBBBBBBH G{SHIFT-*}{SHIFT-*}{rvon}[{rvof}{SHIFT-POUND}{SHIFT-POUND}{SHIFT-+}  {rvon}\{rvof}{CBM-Y}{CBM-Y}C ABBBBBBBBBH G"
10095 print"{up}C C        G {CBM-Z}BBBBBBBBBBB{CBM-D} C         G G"
10100 print"{up}C C        G               C         G G"
10105 print"{up}C C        G YZZZZZZZZZZZ{$a0} C         G G"
10110 print"{up}C C        G {SHIFT-+}           {CBM-*} C         G G"
10115 print"{up}C C        G {SHIFT-+}           {CBM-*} C         G G"
10120 print"{up}C C        G {CBM--}{SHIFT--}{SHIFT--}{SHIFT--}{SHIFT--}{SHIFT--}{SHIFT--}{SHIFT--}{SHIFT--}{SHIFT--}{SHIFT--}{SHIFT--}~ C         G G"
10125 print"{up}C C        G               C         G G"
10130 print"{up}C DEEEEEEEEF    {blk} score {orng}    DEEEEEEEEEF G"
10135 print"{up}C                {blk}     {orng}               "
10140 poke1983,71:poke1984,68:poke2023,70:fort=1985 to 2022:poket,69:nextt
10145 for t=56255 to 56295:poket,8:nextt
10150 return
11000 rem *** normal position ***
11010 poke53269,peek(53269)+4+8
11020 poke53252,169:poke53253,81
11030 poke53254,169:poke53255,102
11999 return
12000 rem *** armpje kwijt ***
12010 poke53269,peek(53269)+2
12020 poke53250,177:poke53251,82
12030 fort=1to30:next
12040 poke2041,241:fort=1to30:next:poke2042,243:poke2043,244
12050 poke2041,242:fort=1to50:next
12060 poke2041,240:poke53269,peek(53269)-2
12999 return
13000 rem *** nog een armpje kwijt ***
13010 poke53269,peek(53269)+2
13020 poke53250,157:poke53251,82
13030 fort=1to30:next
13040 poke2041,241:fort=1to30:next:poke2042,247:poke2043,248
13050 poke2041,242:fort=1to50:next
13060 poke2041,240:poke53269,peek(53269)-2
13999 return
14000 rem *** een beentje kwijt ***
14010 poke53269,peek(53269)+2
14020 poke53250,177:poke53251,97
14030 fort=1to30:next
14040 poke2041,241:fort=1to30:next:poke2043,249
14050 poke2041,242:fort=1to50:next
14060 poke2041,240:poke53269,peek(53269)-2
14999 return
15000 rem *** weer een beentje kwijt ***
15010 poke53269,peek(53269)+2
15020 poke53250,157:poke53251,97
15030 fort=1to30:next
15040 poke2041,241:fort=1to30:next:poke2043,252
15050 poke2041,242:fort=1to50:next
15060 poke2041,240:poke53269,peek(53269)-2
15070 fort=0 to4
15080 poke 53253,peek(53253)+t
15090 poke 53255,peek(53255)+t
15100 nextt
15999 return
16000 rem *** stukje lijf kwijt ***
16010 poke53269,peek(53269)+2
16020 poke53250,163:poke53251,100
16030 fort=1to30:next
16040 poke2041,241:fort=1to30:next:poke2042,253:poke53269,peek(53269)-8
16050 poke2041,242:fort=1to50:next
16060 poke2041,240:poke53269,peek(53269)-2
16070 fort=0 to 4:poke53253,peek(53253)+t:nextt
16999 return
17000 rem *** heel je lijf kwijt ***
17010 poke53269,peek(53269)+2
17020 poke53250,172:poke53251,105
17030 fort=1to30:next
17040 poke2041,241:fort=1to30:next:poke2042,254
17050 poke2041,242:fort=1to50:next
17060 poke2041,240:poke53269,peek(53269)-2
17070 fort=0 to 3:poke53253,peek(53253)+t:nextt:poke53253,109
17999 return
18000 rem *** helemaal kapot ***
18010 poke53269,peek(53269)+2
18020 poke53250,172:poke53251,105
18030 fort=1to30:next
18040 poke2041,241:fort=1to30:next
18050 poke2041,242:fort=1to50:next
18060 poke2041,240:poke53269,peek(53269)-4
18070 poke53271,2:poke53277,2
18074 poke53250,158:poke53251,90
18080 poke2041,241:fort=1to50:next
18090 poke2041,242:fort=1to50:next
18100 poke53269,4
18110 poke2042,255:poke53253,111
18999 return
19000 rem *** het schieten ***
19010 sid=54272:pokesid,254:pokesid+1,1:pokesid+2,153:pokesid+3,9
19020 pokesid+4,134:pokesid+5,64:pokesid+6,250
19030 pokesid+21,6:pokesid+22,20:pokesid+23,240:pokesid+24,79
19040 poke54276,135
19055 poke53269,peek(53269)+1
19060 poke53248,169:poke53249,106
19070 fort=0to30:nextt
19080 poke53287,7:fort=0to30:nextt
19090 poke53287,1:fort=0to30:nextt
19095 poke53269,peek(53269)-1
19100 poke54276,134
19999 return
20000 rem *** sprites initialisen ***
20001 poke53265,peek(53265) and 239
20005 poke53269,0
20010 poke53264,0:poke53275,0
20020 poke53287,2:poke53288,2:poke53289,7:poke53290,7:poke53291,7
20030 poke53285,10:poke53286,0:poke53276,4+8+16
20040 poke53271,0:poke53277,0
20050 poke2040,237:poke2041,240:poke2042,238:poke2043,239:poke2044,245
20999 return
21000 rem *** screen setup ***
21010 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{wht}{rvon}type{$a0}a{rvof}"
21020 print"{rght}{rght}{rght}{rght}{yel}{rvon}TYPE{$a0}A{rvof}"
21030 print"{up}{rght}{rght}{rght}{rght}{wht}{rvon}letter{rvof}"
21040 print"{rght}{rght}{rght}{rght}{yel}{rvon}LETTER{rvof}"
21050 print"{up}{rght}{rght}{rght}{rght}{blu}{rvon}{$a0}{$a0},-{$a0}{$a0}{rvof}"
21060 print"{rght}{rght}{rght}{rght}{rvon}{$a0}{$a0}/.{$a0}{$a0}{rvof}"
21070 print"{up}{rght}{rght}{rght}{rght}{rvon}{$a0}{$a0}01{$a0}{$a0}{rvof}"
21080 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{blu}{rvon}used{rvof}"
21090 print"{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{cyn}{rvon}USED{rvof}"
21100 print"{up}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{blu}{rvon}letters{rvof}"
21110 print"{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{cyn}{rvon}LETTERS{rvof}"
21120 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{wht}"sc
21999 return
22000 rem *** test for chosen letter ***
22010 for t=1 to keer-1
22020 if keer$(keer)=keer$(t) then vraag=1:return
22030 vraag=0:nextt
22040 return
23000 rem *** show wrong letters ***
23100 jaja=jaja+1:l1=asc(keer$(keer)):l2=l1+97-65
23110 print"{home}{wht}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}":print tab(28+jaja);"{rvon}"keer$(keer)"{rvof}";
23115 printtab(108+jaja);"{up}{yel}{rvon}"chr$(l2)"{rvof}"
23999 return
31000 rem *** the intro screen ***
31001 poke 53265,peek(53265) and 239
31002 poke53269,0
31005 print"{clr}{up}{left}";:poke53272,28:printchr$(142)
31010 poke53280,0:poke53281,12
31015 poke53270,24:poke53282,15:poke53283,11
31020 fort=1 to 22: for z=1 to 40:print"{orng}{SHIFT-*}";:next z,t
31025 for t=1944 to 2023:poke t,64:nextt
31026 for t=1024 to 1064:poke t,64:nextt
31027 for t=55296 to 55335:poke t,8: next
31028 for t=56216 to 56295:poke t,8: next
31030 print"{home}{down}{down}{down}"
31040 print"{orng}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}JKKKKKKKKKKKKKKKKKKKKL
31050 print"{up}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}IUQQQQQQQQQQQQQQQQQQXI
31060 print"{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}IRABBBBBBBBBBBBBBBBHSI
31070 print"{up}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}IRC{wht}      the       {orng}GSI
31080 print"{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}IRC{wht}{rvon}{$a0}fantasy{$a0}freaks{$a0}{rvof}{orng}GSI
31090 print"{up}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}IRC{yel}{rvon}{$a0}FANTASY{$a0}FREAKS{$a0}{rvof}{orng}GSI
31100 print"{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}IRC                GSI
31110 print"{up}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}IRC   {blk} present     {orng}GSI
31120 print"{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}IRC                GSI
31130 print"{up}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}IRC {cyn}{rvon}{$a0}cruel{$a0}cannon{rvof} {orng} GSI
31140 print"{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}IRC{blu} {rvon}{$a0}CRUEL{$a0}CANNON{$a0}{rvof} {orng}GSI
31150 print"{up}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}IRDEEEEEEEEEEEEEEEEFSI
31155 print"{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}IWTTTTTTTTTTTTTTTTTTVI
31160 print"{up}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}ONNNNNNNNNNNNNNNNNNNNM
31165 poke53265,peek(53265)or 16
31170 geta$:ifa$<>""then31170
31180 geta$:ifa$=""then31180
31185 poke53265,peek(53265) and239
31190 return
40000 rem *** data lines ***
40010 data adventure,computer,fantasy,milk,tv,miracle,music,egg,hardrock
40020 data house,country,metallica,pool,snooker,football,karate,soccer
40030 data car,aircraft,navy,carrier,basic,monitor,disk,soldier,warrior
40040 data microprose,lucasfilm,ocean,bingbong,tarantula,nintendo,sega
40050 data commodore,software,hardware,bicycle,arcade,simulator
40060 data manual,diskdrive,printer,cartridge,mouse,joystick
40070 data dictionary,library,amiga,philips,sony,music,love,hate,kiss
40080 data sucker,help,vendetta,pirates,tetris,mario,scrabble,memory
40090 data poker,strippoker,magazine,diskbox,guitar,bass
50000 rem *** fantasy freaks
50010 rem *** you may change it if you
50020 rem *** want to, but remember
50030 rem *** this game was coded and
50040 rem *** painted by tice !!!