hovis wow macros

# Assist
# Targets whatever my pet is attacking and then start shooting.  Mostly useful when I'm backing out of melee range or when fighting multiple things.
/target pettarget
/cast [harm, nodead] !Auto Shot

# BGSound
# Toggles whether or not sound is audible when the game client loses focus
/run SetCVar("Sound_EnableSoundWhenGameIsInBG",GetCVar("Sound_EnableSoundWhenGameIsInBG")=="0" and 1 or 0)
/script DEFAULT_CHAT_FRAME:AddMessage(GetCVar("Sound_EnableSoundWhenGameIsInBG")=="0" and "BG sound off" or "BG sound on")

# Train
/follow target
/train target

# Eagle eye
#showtooltip
/cast [@cursor]!Eagle Eye

# Fish
# Either casts arcane shot or fishes depending on if my pole is equipped. I use this so that I can put my primary combat skill on the same button as fishing. Replace Arcane Shot with whatever your primary combat skill is and put this on a very convenient button on your bar.
#showtooltip
/cast [worn:Fishing Pole] Fishing; [noworn:Fishing Pole] Arcane Shot

# Go
# In old versions of WoW, this casts hunter's mark and starts pet attack with a single button push
/cast Hunter's Mark
/petattack

# Pet
# All in one pet macro.  See https://wowwiki.fandom.com/wiki/Useful_macros_for_hunters for all manner of variants
#showtooltip
/cast [modifier:ctrl] Dismiss Pet;[nopet,modifier:alt][target=pet,dead]Revive Pet;[nopet]Call Pet;[combat][modifier:alt]Mend Pet
/stopmacro [combat][nopet][modifier][target=pet,dead]
/cast Feed Pet
/use Wild Hog Shank

# Petattack
# I use these so I can put the button on my normal bars. Not useful if you're using the default pet bar.
#showtooltip
/petattack [harm,nodead]

# Petfollow
#showtooltip
/petfollow

# Travel
# Less useful after you have your mount, but you can just push this button multiple times to get Cheetah and Find Minerals
#showtooltip
/castsequence reset=5 !Aspect of the Cheetah, !Find Minerals