@properties annotation for Xtend

PropertiesProcessor.xtend

package properties

import org.eclipse.xtend.lib.macro.AbstractClassProcessor
import org.eclipse.xtend.lib.macro.Active
import org.eclipse.xtend.lib.macro.TransformationContext
import org.eclipse.xtend.lib.macro.declaration.MutableClassDeclaration

import static extension properties.ASTExtensions.*

/**
 * Adds getters and setters for all fields
 * and default equals, hashcode and toString methods.
 */
@Active(PropertiesProcessor)
public annotation Properties {
}

class PropertiesProcessor extends AbstractClassProcessor {

  override doTransform(MutableClassDeclaration cls, extension TransformationContext context) {
    val extension transformations = new CommonTransformations(context)

    cls.final = true
    cls.persistentState.forEach [ field |
      field.addGetter
      field.addSetter
    ]

    if(!cls.hasDataConstructor) cls.addDataConstructor
    if(!cls.hasEquals) cls.addDataEquals
    if(!cls.hasHashCode) cls.addDataHashCode
    if(!cls.hasToString) cls.addDataToString
  }

}