WASL Parsing Expression Grammar for Pest.rs

grammar.pest

ws = _{ " " | "\t" }
wsln = _{ ws | "\n" }
COMMENT = _{ "/*" ~ (!"*/" ~ ANY)* ~ "*/" | "//" ~ (!"\n" ~ ANY)* ~ "\n"+ }

Program = _{ SOI ~ wsln* ~ (Stmt ~ wsln*)* ~ Stmt? ~ EOI }

Stmt = { AssignmentExpr | ForExpr  }

Identifier = @{ ASCII_ALPHA ~ (ASCII_ALPHANUMERIC | "_")* }

Type = { Identifier }

Declaration = { "let" }

AssignmentExpr = { Declaration ~ ws+ ~ Identifier ~ ws* ~ "=" ~ ws* ~ Expr ~ ";" }

StandaloneExpr = { Expr ~ ";" }

NumberExpr = { Float | Integer }

Integer = { ASCII_DIGIT+ }

Expr = _{ ArithmeticExpr }

Float = { ASCII_DIGIT* ~ "." ~ ASCII_DIGIT+ }

ArithmeticExpr = { AddExpr }

ForExpr = {
	"for" ~ ws* ~ "(" ~ ws* ~ InExpr
     ~ ws* ~ ")" ~ ws* ~ "{" ~ wsln* ~ (Stmt ~ wsln*)* ~ "}"
}

InExpr = { Declaration  ~ ws+ 
    ~ Identifier  ~ ws+ ~ "in"  ~ ws+ ~ Identifier }

AddExpr = {
	MulExpr ~ ws* ~ "+" ~ ws* ~ AddExpr
    | MulExpr ~ ws* ~ "-" ~ ws* ~ AddExpr
    | MulExpr
}

ArrayExpr = { "[" ~ wsln* ~ (ArithmeticExpr ~ ws* ~ "," ~ wsln*)* 
  ~ (ArithmeticExpr ~ ws* ~ ","* ~ wsln*)* ~ "]" }

UnitExpr = {
	"(" ~ ws* ~ ArithmeticExpr ~ ws* ~ ")"
    | "+" ~ ws* ~ UnitExpr
    | "-" ~ ws* ~ UnitExpr
    | Identifier
    | NumberExpr
    | ArrayExpr
}

MulExpr = { 
  UnitExpr ~ ws* ~ "*" ~ ws* ~ MulExpr 
  | UnitExpr ~ ws* ~ "/" ~ ws* ~ MulExpr 
  | UnitExpr
}