smooll.nix

# Smooll the small nix shell
{ pkgs, ... }:

{
  name,
  system ? pkgs.system,
  packages ? [ ],
  shellHook ? "",
  env ? { },
  coreutils ? pkgs.coreutils,
}:

let
  inherit (builtins)
    toJSON
    placeholder
    mapAttrs
    concatStringsSep
    attrNames
    isList
    ;
  listToStr = ls: if (isList ls) then concatStringsSep " " ls else ls;

  inputs = [ coreutils ] ++ packages;
  binPaths = pkgs.lib.makeBinPath inputs;
  unsetScript = concatStringsSep "\n" (
    map (name: "unset ${name}") ((attrNames requiredVariables) ++ (attrNames drvAttrs))
  );
  shellHook' = ''
    export PATH="''${PATH}''${PATH:+:}${binPaths}"
    ${shellHook}
    ${unsetScript}
  '';

  requiredVariables = {
    out = placeholder "out";
    outputs = "out";
    shellHook = shellHook';
  };
  variables = mapAttrs (_: value: {
    type = "exported";
    inherit value;
  }) ((mapAttrs (_: listToStr) env) // requiredVariables);

  drvAttrs = {
    inherit name system;
    builder = pkgs.stdenv.shell;
    args = [
      "-c"
      ''{ export; } >> "$out"''
    ];
    varsJSON = toJSON { inherit variables; };
  };

  drv = derivation (
    drvAttrs
    // env
    // {
      # Create a minimal stdenv setup script
      #   - try to write metadata as JSON `$out`
      #   - if `$out` can't be written to assume that `nix-shell` is being used
      #     and eval shellHook
      stdenv = pkgs.writeTextDir "setup" ''
        writeOut() { echo "$varsJSON" > "$out"; }
        if { writeOut 2>&1; } >/dev/null; then :
        else
          ${shellHook'}
        fi
      '';
    }
  );
in
drv