gradle Export jar files

gistfile1.txt

task exportApiServiceParametersJar(type : Jar) {
    from { sourceSets.main.output.classesDirs } {
        include "com/foo/api/service/parameters/**"
    }
    dependsOn compileJava
}
task exportApiPagingJar(type : Jar) {
    from { sourceSets.main.output.classesDirs } {
        include "com/foo/api/paging/**"
    }
    dependsOn compileJava
}

publishing {
    repositories {
        maven {
            credentials {
                username project.getProperty("nexusPublishUsername")
                password project.getProperty("nexusPublishPassword")
            }
            if (project.version.endsWith('-SNAPSHOT')) {
                url "https://nexus/repository/maven-snapshots/"
            } else {
                url "https://nexus/repository/maven-releases/"
            }
        }
    }
    publications {
        exportApiServiceParameters(MavenPublication) {
            groupId = 'com.foo.api.service'
            artifactId = 'parameters'
            artifact exportApiServiceParametersJar
        }
        exportApiPaging(MavenPublication) {
            groupId = 'com.foo.api'
            artifactId = 'paging'
            artifact exportApiPagingJar
        }
    }
}