Custom tool for method navigation of a class

aTrait := TAsyncStream.	"Paint a tree of classes which use a specified trait. Click to list all the methods. Click with Modifier (command on mac, and ctrl on windows and linux) only to filter out the methods overriden by that class."
notInterestedForNow := 'Async'.
classesFilter := GtSearchImageClassesFilter new
		select: [ :class | class usesTrait: aTrait ].
classes := classesFilter result toArray wait asSet.
superClasses := classes flatCollect: [ :class | class allSuperclasses ].
stencilForNodes := [ :class | 
	| element |
	element := BrLabel new
			text: class name;
			background: Color paleOrange;
			aptitude: BrGlamorousLabelAptitude new;
			border: (BlBorder paint: Color veryLightGray);
			when: BlClickEvent
				do: [ :anEvent | 
					| methodsFilter |
					anEvent consumed: true.
					((superClasses includes: class) and: [ (classes includes: class) not ])
						ifFalse: [ methodsFilter := GtSearchMethodsInInstanceAndClassSideFilter forClass: class.
							anEvent modifiers isPrimaryModifier
								ifTrue: [ methodsFilter := methodsFilter & GtSearchNonTraitMethodsFilter new ].
							anEvent currentTarget phlow spawnObject: methodsFilter ] ].
	(class name beginsWith: notInterestedForNow) not
		ifTrue: [ element background: Color lightOrange ].
	((superClasses includes: class) and: [ (classes includes: class) not ])
		ifTrue: [ element background: Color lightYellow ].
	element ].
mondrian := GtMondrian new.
mondrian nodes
	stencil: stencilForNodes;
	with: classes , superClasses.
mondrian edges connectToAll: #subclasses.
mondrian layout horizontalTree.
mondrian