Microsoft Edge Uninstaller [Windows 10 LTSC 2021/21H1 Edition]

microsoft_edge_uninstaller_21h1_ltsc.bat

@echo off
@title Microsoft Edge Uninstaller [Windows 10 LTSC 2021/21H1 Edition]
ver

echo+
goto check_admin_permissions
:check_admin_permissions
	echo Script must Run as Administrator! Detecting permissions...
	net session >nul 2>&1
	if %errorLevel% == 0 (
		echo Success!
	) else (
		echo Failure. Please, Run script as Administrator!
		echo+
		echo Exiting...
		timeout /t 5 /nobreak >nul
		exit /b
	)

echo+
echo Press any key to remove Microsoft Edge from Windows 10...
pause >nul

echo+
echo Microsoft Edge [Chromium] uninstalling...

cd /d "%ProgramFiles(x86)%\Microsoft"
for /f "tokens=1 delims=\" %%i in ('dir /B /A:D "%ProgramFiles(x86)%\Microsoft\Edge\Application" ^| find "."') do (set "edge_chromium_package_version=%%i")
if defined edge_chromium_package_version (
		echo Removing %edge_chromium_package_version%...
		EdgeWebView\Application\%edge_chromium_package_version%\Installer\setup.exe --uninstall --force-uninstall --msedgewebview --system-level --verbose-logging
		Edge\Application\%edge_chromium_package_version%\Installer\setup.exe --uninstall --force-uninstall --msedge --system-level --verbose-logging
		EdgeCore\%edge_chromium_package_version%\Installer\setup.exe --uninstall --force-uninstall --msedge --system-level --verbose-logging
	) else (
		echo Microsoft Edge [Chromium] not found, skipping.
	)
cd /d "%~dp0"

echo+
echo Microsoft Edge [Legacy/UWP] uninstalling...

for /f "tokens=8 delims=\" %%i in ('reg query "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\Packages" ^| findstr "Microsoft-Windows-Internet-Browser-Package" ^| findstr "~~"') do (set "edge_legacy_package_version=%%i")
if defined edge_legacy_package_version (
		echo Removing %edge_legacy_package_version%...
		reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\Packages\%edge_legacy_package_version%" /v Visibility /t REG_DWORD /d 1 /f
		reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\Packages\%edge_legacy_package_version%\Owners" /va /f
		dism /online /Remove-Package /PackageName:%edge_legacy_package_version%
		powershell.exe -Command "Get-AppxPackage *edge* | Remove-AppxPackage" >nul
	) else (
		echo Microsoft Edge [Legacy/UWP] not found, skipping.
	)

echo+
echo Done!
echo Press any key to exit.

rem by @ishad0w
pause >nul
exit /b

Changelog:

Revision 1 (21-12-2021):

• Initial Release, tested on 19044.{1288-1415} build.

Revision 2 (22-12-2021):

• Windows build shows at launch.
• Permission check update. Exiting if running not as an administrator.
• Script refactoring. Removed all hard-coded versions.
• Tested on fresh installed LTSC 2021 (19044.1288) and after updating to 19044.1415 (cumulative update).

Discontinued.

Please, use AveYo (Microsoft Edge Removal) instead.