Adding SpotBugs v1.7.1 to gradle v5 project

build.gradle

import com.github.spotbugs.SpotBugsTask
// ...

plugins {
    // ...
    id "com.github.spotbugs" version "1.7.1"
}

// ...

test.dependsOn spotbugsMain, spotbugsTest

/**
 * SpotBugs config
 *
 * Settings options from:
 * - http://gradle.monochromeroad.com/docs/dsl/org.gradle.api.plugins.quality.FindBugsExtension.html
 * - https://spotbugs.readthedocs.io/en/latest/running.html#output-options
 * - {@link SpotBugsTask}
 * - ./config/spotbugs/excludeFilter.xml
 */
spotbugs {
    showProgress = true
    reportLevel = 'high'
    ignoreFailures = false
    excludeFilterConfig = resources.text.fromFile("$rootProject.projectDir/excludeFilter.xml")
    extraArgs = ['-longBugCodes','true']
}
tasks.withType(SpotBugsTask) {
    reports {
        xml {
            enabled = false
        }
        text {
            enabled = true
        }
    }
}
// As I could not find reporting plugin this is what prints
// failures to console
// Credit goes to https://github.com/Opalo and his implementation: https://github.com/Opalo/stackoverflow/blob/master/28069712/build.gradle
tasks.create("printSpotbugsReports") {
    doLast {
        spotbugsMain.reports.text?.destination?.eachLine {
            println 'Failure: ' + it
        }
        spotbugsTest.reports.text?.destination?.eachLine {
            println 'Failure: ' + it
        }
    }
}
spotbugsMain.finalizedBy printSpotbugsReports
spotbugsTest.finalizedBy printSpotbugsReports

excludeFilter.xml

<FindBugsFilter>
    <Match>
        <Package name="~.*\.foobar.*"/>
    </Match>
</FindBugsFilter>